OBJ_VLINE
Đường Dọc.
Ghi chú
Khi vẽ một đường dọc, có thể thiết lập chế độ hiển thị đường cho tất cả các cửa sổ biểu đồ (thuộc tính OBJPROP_RAY).
Ví dụ
Script sau tạo và di chuyển đường dọc trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên bản" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Đường Dọc\"."
#property description "Ngày điểm neo được đặt theo phần trăm của"
#property description "chiều rộng cửa sổ biểu đồ tính bằng thanh."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="VLine"; // Tên đường
input int InpDate=25; // Ngày sự kiện, %
input color InpColor=clrRed; // Màu đường
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Kiểu đường
input int InpWidth=3; // Độ rộng đường
input bool InpBack=false; // Đường nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpRay=true; // Tiếp tục đường xuống dưới
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đường dọc |
//+------------------------------------------------------------------+
bool VLineCreate(const long chart_ID=0, // ID biểu đồ
const string name="VLine", // Tên đường
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian đường
const color clr=clrRed, // Màu đường
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường
const int width=1, // Độ rộng đường
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool ray=true, // Tiếp tục đường xuống dưới
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- nếu thời gian đường không được đặt, vẽ nó qua thanh cuối cùng
if(!time)
time=TimeCurrent();
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo một đường dọc
if(!ObjectCreate(chart_ID,name,OBJ_VLINE,sub_window,time,0))
{
Print(__FUNCTION__,
": không thể tạo đường dọc! Mã lỗi = ",GetLastError());
return(false);
}
//--- đặt màu đường
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu hiển thị đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển đường bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- bật (true) hoặc tắt (false) chế độ hiển thị đường trong các cửa sổ phụ của biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_RAY,ray);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển đường dọc |
//+------------------------------------------------------------------+
bool VLineMove(const long chart_ID=0, // ID biểu đồ
const string name="VLine", // Tên đường
datetime time=0) // Thời gian đường
{
//--- nếu thời gian đường không được đặt, di chuyển đường tới thanh cuối cùng
if(!time)
time=TimeCurrent();
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển đường dọc
if(!ObjectMove(chart_ID,name,0,time,0))
{
Print(__FUNCTION__,
": không thể di chuyển đường dọc! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đường dọc |
//+------------------------------------------------------------------+
bool VLineDelete(const long chart_ID=0, // ID biểu đồ
const string name="VLine") // Tên đường
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đường dọc
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đường dọc! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate<0 || InpDate>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- mảng để lưu trữ giá trị ngày sẽ được sử dụng
//--- để đặt và thay đổi tọa độ điểm neo của đường
datetime date[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- xác định các điểm để vẽ đường
int d=InpDate*(bars-1)/100;
//--- tạo một đường dọc
if(!VLineCreate(0,InpName,0,date[d],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpRay,InpHidden,InpZOrder))
return;
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển đường
//--- bộ đếm vòng lặp
int h_steps=bars/2;
//--- di chuyển đường
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d<bars-1)
d+=1;
//--- di chuyển điểm
if(!VLineMove(0,InpName,date[d]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.03 giây trì hoãn
Sleep(30);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa kênh khỏi biểu đồ
VLineDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}