GetMicrosecondCount

Hàm GetMicrosecondCount() trả về số micro giây đã trôi qua kể từ khi chương trình MQL5 khởi động.

ulong  GetMicrosecondCount();

Giá trị trả về

Giá trị kiểu ulong.

Ví dụ:

//+------------------------------------------------------------------+
//| Hàm kiểm tra                                                    |
//+------------------------------------------------------------------+
void Test()
  {
   int    res_int=0;
   double res_double=0;
   //---
   for(int i=0;i<10000;i++)
     {
      res_int+=i*i;
      res_int++;
      res_double+=i*i;
      res_double++;
     }
  }
//+------------------------------------------------------------------+
//| Hàm khởi động chương trình script                               |
//+------------------------------------------------------------------+
void OnStart()
  {
   uint   ui=0,ui_max=0,ui_min=INT_MAX;
   ulong  ul=0,ul_max=0,ul_min=INT_MAX;
   //--- số lần đo
   for(int count=0;count<1000;count++)
     {
      uint  ui_res=0;
      ulong ul_res=0;
      //---
      for(int n=0;n<2;n++)
        {
         //--- chọn loại đo
         if(n==0) ui=GetTickCount();
         else     ul=GetMicrosecondCount();
         //--- thực thi mã
         Test();
         //--- thêm kết quả đo (tùy thuộc vào loại)
         if(n==0) ui_res+=GetTickCount()-ui;
         else     ul_res+=GetMicrosecondCount()-ul;
        }
      //--- tính toán thời gian tối thiểu và tối đa cho cả hai phép đo
      if(ui_min>ui_res) ui_min=ui_res;
      if(ui_max<ui_res) ui_max=ui_res;
      if(ul_min>ul_res) ul_min=ul_res;
      if(ul_max<ul_res) ul_max=ul_res;
     }
   //---
   Print("Sai số GetTickCount (msec): ",ui_max-ui_min);
   Print("Sai số GetMicrosecondCount (msec): ",DoubleToString((ul_max-ul_min)/1000.0,2));
  }

Xem thêm

Date and Time, GetTickCount, GetTickCount64