OBJ_EDIT
Đối tượng Chỉnh sửa.
Ghi chú
Tọa độ điểm neo được thiết lập bằng pixel. Bạn có thể chọn góc neo của Edit từ danh sách liệt kê ENUM_BASE_CORNER.
Bạn cũng có thể chọn một trong những kiểu căn chỉnh văn bản bên trong Edit từ danh sách liệt kê ENUM_ALIGN_MODE.
Ví dụ
Script sau tạo và di chuyển đối tượng Edit trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên trạng trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo đối tượng \"Edit\"."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Edit"; // Tên đối tượng
input string InpText="Text"; // Văn bản đối tượng
input string InpFont="Arial"; // Phông chữ
input int InpFontSize=14; // Kích thước phông chữ
input ENUM_ALIGN_MODE InpAlign=ALIGN_CENTER; // Kiểu căn chỉnh văn bản
input bool InpReadOnly=false; // Quyền chỉnh sửa
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // Góc biểu đồ để neo
input color InpColor=clrBlack; // Màu văn bản
input color InpBackColor=clrWhite; // Màu nền
input color InpBorderColor=clrBlack; // Màu viền
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đối tượng Edit |
//+------------------------------------------------------------------+
bool EditCreate(const long chart_ID=0, // ID biểu đồ
const string name="Edit", // Tên đối tượng
const int sub_window=0, // Chỉ số cửa sổ phụ
const int x=0, // Tọa độ X
const int y=0, // Tọa độ Y
const int width=50, // Chiều rộng
const int height=18, // Chiều cao
const string text="Text", // Văn bản
const string font="Arial", // Phông chữ
const int font_size=10, // Kích thước phông chữ
const ENUM_ALIGN_MODE align=ALIGN_CENTER, // Kiểu căn chỉnh
const bool read_only=false, // Khả năng chỉnh sửa
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // Góc biểu đồ để neo
const color clr=clrBlack, // Màu văn bản
const color back_clr=clrWhite, // Màu nền
const color border_clr=clrNONE, // Màu viền
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo trường chỉnh sửa
if(!ObjectCreate(chart_ID,name,OBJ_EDIT,sub_window,0,0))
{
Print(__FUNCTION__,
": không thể tạo đối tượng \"Edit\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập tọa độ đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- thiết lập kích thước đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- thiết lập văn bản
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- thiết lập phông chữ văn bản
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- thiết lập kích thước phông chữ
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- thiết lập kiểu căn chỉnh văn bản trong đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_ALIGN,align);
//--- bật (true) hoặc hủy (false) chế độ chỉ đọc
ObjectSetInteger(chart_ID,name,OBJPROP_READONLY,read_only);
//--- thiết lập góc biểu đồ, mà tọa độ đối tượng được xác định tương đối với nó
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- thiết lập màu văn bản
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập màu nền
ObjectSetInteger(chart_ID,name,OBJPROP_BGCOLOR,back_clr);
//--- thiết lập màu viền
ObjectSetInteger(chart_ID,name,OBJPROP_BORDER_COLOR,border_clr);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển đối tượng Edit |
//+------------------------------------------------------------------+
bool EditMove(const long chart_ID=0, // ID biểu đồ
const string name="Edit", // Tên đối tượng
const int x=0, // Tọa độ X
const int y=0) // Tọa độ Y
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ X của đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ Y của đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi kích thước đối tượng Edit |
//+------------------------------------------------------------------+
bool EditChangeSize(const long chart_ID=0, // ID biểu đồ
const string name="Edit", // Tên đối tượng
const int width=0, // Chiều rộng
const int height=0) // Chiều cao
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi kích thước đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": không thể thay đổi chiều rộng đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": không thể thay đổi chiều cao đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi văn bản của đối tượng Edit |
//+------------------------------------------------------------------+
bool EditTextChange(const long chart_ID=0, // ID biểu đồ
const string name="Edit", // Tên đối tượng
const string text="Text") // Văn bản
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi văn bản đối tượng
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": không thể thay đổi văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Lấy văn bản của đối tượng Edit |
//+------------------------------------------------------------------+
bool EditTextGet(string &text, // Văn bản
const long chart_ID=0, // ID biểu đồ
const string name="Edit") // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- lấy văn bản đối tượng
if(!ObjectGetString(chart_ID,name,OBJPROP_TEXT,0,text))
{
Print(__FUNCTION__,
": không thể lấy văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đối tượng Edit |
//+------------------------------------------------------------------+
bool EditDelete(const long chart_ID=0, // ID biểu đồ
const string name="Edit") // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nhãn
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đối tượng \"Edit\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kích thước cửa sổ biểu đồ
long x_distance;
long y_distance;
//--- thiết lập kích thước cửa sổ
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Không thể lấy chiều rộng biểu đồ! Mã lỗi = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Không thể lấy chiều cao biểu đồ! Mã lỗi = ",GetLastError());
return;
}
//--- xác định bước thay đổi trường chỉnh sửa
int x_step=(int)x_distance/64;
//--- thiết lập tọa độ và kích thước trường chỉnh sửa
int x=(int)x_distance/8;
int y=(int)y_distance/2;
int x_size=(int)x_distance/8;
int y_size=InpFontSize*2;
//--- lưu văn bản vào biến cục bộ
string text=InpText;
//--- tạo trường chỉnh sửa
if(!EditCreate(0,InpName,0,x,y,x_size,y_size,InpText,InpFont,InpFontSize,InpAlign,InpReadOnly,
InpCorner,InpColor,InpBackColor,InpBorderColor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- kéo dài trường chỉnh sửa
while(x_size-x<x_distance*5/8)
{
//--- tăng chiều rộng trường chỉnh sửa
x_size+=x_step;
if(!EditChangeSize(0,InpName,x_size,y_size))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ và đợi 0.05 giây
ChartRedraw();
Sleep(50);
}
//--- nửa giây trì hoãn
Sleep(500);
//--- thay đổi văn bản
for(int i=0;i<20;i++)
{
//--- thêm "+" vào đầu và cuối
text="+"+text+"+";
if(!EditTextChange(0,InpName,text))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ và đợi 0.1 giây
ChartRedraw();
Sleep(100);
}
//--- nửa giây trì hoãn
Sleep(500);
//--- xóa trường chỉnh sửa
EditDelete(0,InpName);
ChartRedraw();
//--- đợi 1 giây
Sleep(1000);
//---
}