OBJ_HLINE
Đường Ngang.
Ví dụ
Script sau tạo và di chuyển đường ngang trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên bản" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Đường Ngang\"."
#property description "Giá điểm neo được đặt theo phần trăm chiều cao của"
#property description "cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="HLine"; // Tên đường
input int InpPrice=25; // Giá đường, %
input color InpColor=clrRed; // Màu đường
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Kiểu đường
input int InpWidth=3; // Độ rộng đường
input bool InpBack=false; // Đường nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đường ngang |
//+------------------------------------------------------------------+
bool HLineCreate(const long chart_ID=0, // ID biểu đồ
const string name="HLine", // Tên đường
const int sub_window=0, // Chỉ số cửa sổ phụ
double price=0, // Giá đường
const color clr=clrRed, // Màu đường
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường
const int width=1, // Độ rộng đường
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- nếu giá không được đặt, đặt nó ở mức giá Bid hiện tại
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo một đường ngang
if(!ObjectCreate(chart_ID,name,OBJ_HLINE,sub_window,0,price))
{
Print(__FUNCTION__,
": không thể tạo đường ngang! Mã lỗi = ",GetLastError());
return(false);
}
//--- đặt màu đường
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu hiển thị đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển đường bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển đường ngang |
//+------------------------------------------------------------------+
bool HLineMove(const long chart_ID=0, // ID biểu đồ
const string name="HLine", // Tên đường
double price=0) // Giá đường
{
//--- nếu giá đường không được đặt, di chuyển nó tới mức giá Bid hiện tại
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển đường ngang
if(!ObjectMove(chart_ID,name,0,0,price))
{
Print(__FUNCTION__,
": không thể di chuyển đường ngang! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đường ngang |
//+------------------------------------------------------------------+
bool HLineDelete(const long chart_ID=0, // ID biểu đồ
const string name="HLine") // Tên đường
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đường ngang
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đường ngang! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpPrice<0 || InpPrice>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ điểm neo của đường
double price[];
//--- cấp phát bộ nhớ
ArrayResize(price,accuracy);
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ đường
int p=InpPrice*(accuracy-1)/100;
//--- tạo một đường ngang
if(!HLineCreate(0,InpName,0,price[p],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển đường
//--- bộ đếm vòng lặp
int v_steps=accuracy/2;
//--- di chuyển đường
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p<accuracy-1)
p+=1;
//--- di chuyển điểm
if(!HLineMove(0,InpName,price[p]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa khỏi biểu đồ
HLineDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}