OBJ_GANNLINE
Đường Gann.
Ghi chú
Đối với Đường Gann, có thể chỉ định chế độ tiếp tục hiển thị của nó sang bên phải và/hoặc bên trái (thuộc tính OBJPROP_RAY_RIGHT và OBJPROP_RAY_LEFT tương ứng).
Cả góc Gann với tỷ lệ và tọa độ của điểm neo thứ hai đều có thể được sử dụng để đặt độ dốc của đường.
Ví dụ
Script sau đây tạo và di chuyển Đường Gann trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên bản trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Đường Gann\"."
#property description "Tọa độ điểm neo được đặt theo phần trăm của"
#property description "kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="GannLine"; // Tên đường
input int InpDate1=20; // Ngày của điểm thứ nhất, %
input int InpPrice1=75; // Giá của điểm thứ nhất, %
input int InpDate2=80; // Ngày của điểm thứ hai, %
input double InpAngle=0.0; // Góc Gann
input double InpScale=1.0; // Tỷ lệ
input color InpColor=clrRed; // Màu đường
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Kiểu đường
input int InpWidth=2; // Độ rộng đường
input bool InpBack=false; // Đường nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpRayLeft=false; // Tiếp tục đường sang trái
input bool InpRayRight=true; // Tiếp tục đường sang phải
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo Đường Gann theo tọa độ, góc và tỷ lệ |
//+------------------------------------------------------------------+
bool GannLineCreate(const long chart_ID=0, // ID biểu đồ
const string name="GannLine", // Tên đường
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
double price1=0, // Giá điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
const double angle=1.0, // Góc Gann
const double scale=1.0, // Tỷ lệ
const color clr=clrRed, // Màu đường
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường
const int width=1, // Độ rộng đường
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool ray_left=false, // Tiếp tục đường sang trái
const bool ray_right=true, // Tiếp tục đường sang phải
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- đặt tọa độ các điểm neo nếu chúng chưa được đặt
ChangeGannLineEmptyPoints(time1,price1,time2);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo Đường Gann theo tọa độ đã cho
//--- tọa độ của điểm neo thứ hai được xác định lại tự động
//--- sau khi góc Gann và/hoặc tỷ lệ thay đổi,
if(!ObjectCreate(chart_ID,name,OBJ_GANNLINE,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": không thể tạo \"Đường Gann\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thay đổi góc Gann
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- thay đổi tỷ lệ (số pip trên mỗi thanh)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- đặt màu đường
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu hiển thị đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ tô sáng đường để di chuyển
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị đường sang trái
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị đường sang phải
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo của Đường Gann |
//+------------------------------------------------------------------+
bool GannLinePointChange(const long chart_ID=0, // ID biểu đồ
const string name="GannLine", // Tên đường
const int point_index=0, // Chỉ số điểm neo
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được đặt, di chuyển nó tới thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo của đường
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi góc Gann |
//+------------------------------------------------------------------+
bool GannLineAngleChange(const long chart_ID=0, // ID biểu đồ
const string name="GannLine", // Tên đường
const double angle=1.0) // Góc Gann
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi góc Gann
if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
{
Print(__FUNCTION__,
": không thể thay đổi góc Gann! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi tỷ lệ của Đường Gann |
//+------------------------------------------------------------------+
bool GannLineScaleChange(const long chart_ID=0, // ID biểu đồ
const string name="GannLine", // Tên đường
const double scale=1.0) // Tỷ lệ
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi tỷ lệ (số pip trên mỗi thanh)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": không thể thay đổi tỷ lệ! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa Đường Gann khỏi biểu đồ |
//+------------------------------------------------------------------+
bool GannLineDelete(const long chart_ID=0, // ID biểu đồ
const string name="GannLine") // Tên đường
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đường Gann
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa \"Đường Gann\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo Đường Gann và đặt mặc định |
//| cho những điểm trống |
//+------------------------------------------------------------------+
void ChangeGannLineEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- nếu thời gian của điểm thứ hai không được đặt, nó sẽ nằm trên thanh hiện tại
if(!time2)
time2=TimeCurrent();
//--- nếu thời gian của điểm thứ nhất không được đặt, nó nằm cách 9 thanh về bên trái từ điểm thứ hai
if(!time1)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- đặt điểm thứ nhất cách 9 thanh về bên trái từ điểm thứ hai
time1=temp[0];
}
//--- nếu giá của điểm thứ nhất không được đặt, nó sẽ có giá trị Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ các điểm neo của đường
datetime date[];
double price[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ Đường Gann
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- tạo Đường Gann
if(!GannLineCreate(0,InpName,0,date[d1],price[p1],date[d2],InpAngle,InpScale,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển điểm neo của đường và thay đổi góc
//--- bộ đếm vòng lặp
int v_steps=accuracy/2;
//--- di chuyển điểm neo thứ nhất theo chiều dọc
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p1>1)
p1-=1;
//--- di chuyển điểm
if(!GannLinePointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- nửa giây trì hoãn
Sleep(500);
//--- xác định giá trị hiện tại của góc Gann (đã thay đổi
//--- sau khi di chuyển điểm neo thứ nhất)
double curr_angle;
if(!ObjectGetDouble(0,InpName,OBJPROP_ANGLE,0,curr_angle))
return;
//--- bộ đếm vòng lặp
v_steps=accuracy/8;
//--- thay đổi góc Gann
for(int i=0;i<v_steps;i++)
{
if(!GannLineAngleChange(0,InpName,curr_angle-0.05*i))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa đường khỏi biểu đồ
GannLineDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}