OBJ_CHART
Đối tượng Biểu đồ.
Ghi chú
Đối tượng loại OBJ_CHART không được hỗ trợ (không hiển thị) trong quá trình kiểm tra trực quan.
Tọa độ điểm neo được thiết lập bằng pixel. Bạn có thể chọn góc neo từ danh sách liệt kê ENUM_BASE_CORNER.
Ký hiệu, chu kỳ và tỷ lệ có thể được chọn cho đối tượng Biểu đồ. Chế độ hiển thị tỷ lệ giá và ngày cũng có thể được bật/tắt.
Ví dụ
Script sau tạo và di chuyển đối tượng Biểu đồ trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo đối tượng \"Chart\"."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Chart"; // Tên đối tượng
input string InpSymbol="EURUSD"; // Ký hiệu
input ENUM_TIMEFRAMES InpPeriod=PERIOD_H1; // Chu kỳ
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // Góc neo
input int InpScale=2; // Tỷ lệ
input bool InpDateScale=true; // Hiển thị tỷ lệ thời gian
input bool InpPriceScale=true; // Hiển thị tỷ lệ giá
input color InpColor=clrRed; // Màu viền khi được làm nổi bật
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Kiểu đường viền khi được làm nổi bật
input int InpPointWidth=1; // Kích thước điểm để di chuyển
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=true; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đối tượng Biểu đồ |
//+------------------------------------------------------------------+
bool ObjectChartCreate(const long chart_ID=0, // ID biểu đồ
const string name="Chart", // Tên đối tượng
const int sub_window=0, // Chỉ số cửa sổ phụ
const string symbol="EURUSD", // Ký hiệu
const ENUM_TIMEFRAMES period=PERIOD_H1, // Chu kỳ
const int x=0, // Tọa độ X
const int y=0, // Tọa độ Y
const int width=300, // Chiều rộng
const int height=200, // Chiều cao
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // Góc neo
const int scale=2, // Tỷ lệ
const bool date_scale=true, // Hiển thị tỷ lệ thời gian
const bool price_scale=true, // Hiển thị tỷ lệ giá
const color clr=clrRed, // Màu viền khi làm nổi bật
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường khi làm nổi bật
const int point_width=1, // Kích thước điểm di chuyển
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo đối tượng Biểu đồ
if(!ObjectCreate(chart_ID,name,OBJ_CHART,sub_window,0,0))
{
Print(__FUNCTION__,
": không thể tạo đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập tọa độ đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- thiết lập kích thước đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- thiết lập góc biểu đồ, tương ứng với tọa độ điểm
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- thiết lập ký hiệu
ObjectSetString(chart_ID,name,OBJPROP_SYMBOL,symbol);
//--- thiết lập chu kỳ
ObjectSetInteger(chart_ID,name,OBJPROP_PERIOD,period);
//--- thiết lập tỷ lệ
ObjectSetInteger(chart_ID,name,OBJPROP_CHART_SCALE,scale);
//--- hiển thị (true) hoặc ẩn (false) tỷ lệ thời gian
ObjectSetInteger(chart_ID,name,OBJPROP_DATE_SCALE,date_scale);
//--- hiển thị (true) hoặc ẩn (false) tỷ lệ giá
ObjectSetInteger(chart_ID,name,OBJPROP_PRICE_SCALE,price_scale);
//--- thiết lập màu viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập kích thước điểm neo để di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thiết lập ký hiệu và khung thời gian của đối tượng Biểu đồ |
//+------------------------------------------------------------------+
bool ObjectChartSetSymbolAndPeriod(const long chart_ID=0, // ID biểu đồ (không phải ID của đối tượng Biểu đồ)
const string name="Chart", // Tên đối tượng
const string symbol="EURUSD", // Ký hiệu
const ENUM_TIMEFRAMES period=PERIOD_H1) // Khung thời gian
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thiết lập ký hiệu và khung thời gian của đối tượng Biểu đồ
if(!ObjectSetString(chart_ID,name,OBJPROP_SYMBOL,symbol))
{
Print(__FUNCTION__,
": không thể thiết lập ký hiệu cho đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_PERIOD,period))
{
Print(__FUNCTION__,
": không thể thiết lập chu kỳ cho đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển đối tượng Biểu đồ |
//+------------------------------------------------------------------+
bool ObjectChartMove(const long chart_ID=0, // ID biểu đồ (không phải ID của đối tượng Biểu đồ)
const string name="Chart", // Tên đối tượng
const int x=0, // Tọa độ X
const int y=0) // Tọa độ Y
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ X của đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ Y của đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi kích thước đối tượng Biểu đồ |
//+------------------------------------------------------------------+
bool ObjectChartChangeSize(const long chart_ID=0, // ID biểu đồ (không phải ID của đối tượng Biểu đồ)
const string name="Chart", // Tên đối tượng
const int width=300, // Chiều rộng
const int height=200) // Chiều cao
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi kích thước đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": không thể thay đổi chiều rộng của đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": không thể thay đổi chiều cao của đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Lấy ID của đối tượng Biểu đồ |
//+------------------------------------------------------------------+
long ObjectChartGetID(const long chart_ID=0, // ID biểu đồ (không phải ID của đối tượng Biểu đồ)
const string name="Chart") // Tên đối tượng
{
//--- chuẩn bị biến để lấy ID của đối tượng Biểu đồ
long id=-1;
//--- đặt lại giá trị lỗi
ResetLastError();
//--- lấy ID
if(!ObjectGetInteger(chart_ID,name,OBJPROP_CHART_ID,0,id))
{
Print(__FUNCTION__,
": không thể lấy ID của đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
}
//--- trả về kết quả
return(id);
}
//+------------------------------------------------------------------+
//| Xóa đối tượng Biểu đồ |
//+------------------------------------------------------------------+
bool ObjectChartDelete(const long chart_ID=0, // ID biểu đồ (không phải ID của đối tượng Biểu đồ)
const string name="Chart") // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nút
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đối tượng \"Chart\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- lấy số lượng ký hiệu trong Market Watch
int symbols=SymbolsTotal(true);
//--- kiểm tra xem ký hiệu với tên được chỉ định có trong danh sách ký hiệu không
bool exist=false;
for(int i=0;i<symbols;i++)
if(InpSymbol==SymbolName(i,true))
{
exist=true;
break;
}
if(!exist)
{
Print("Lỗi! ",InpSymbol," ký hiệu không có trong \"Market Watch\"!");
return;
}
//--- kiểm tra tính hợp lệ của tham số đầu vào
if(InpScale<0 || InpScale>5)
{
Print("Lỗi! Giá trị không hợp lệ của tham số đầu vào!");
return;
}
//--- kích thước cửa sổ biểu đồ
long x_distance;
long y_distance;
//--- thiết lập kích thước cửa sổ
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Không thể lấy chiều rộng biểu đồ! Mã lỗi = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Không thể lấy chiều cao biểu đồ! Mã lỗi = ",GetLastError());
return;
}
//--- thiết lập tọa độ và kích thước của đối tượng Biểu đồ
int x=(int)x_distance/16;
int y=(int)y_distance/16;
int x_size=(int)x_distance*7/16;
int y_size=(int)y_distance*7/16;
//--- tạo đối tượng Biểu đồ
if(!ObjectChartCreate(0,InpName,0,InpSymbol,InpPeriod,x,y,x_size,y_size,InpCorner,InpScale,InpDateScale,
InpPriceScale,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- mở rộng đối tượng Biểu đồ
int steps=(int)MathMin(x_distance*7/16,y_distance*7/16);
for(int i=0;i<steps;i++)
{
//--- thay đổi kích thước
x_size+=1;
y_size+=1;
if(!ObjectChartChangeSize(0,InpName,x_size,y_size))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ và đợi 0.01 giây
ChartRedraw();
Sleep(10);
}
//--- trì hoãn nửa giây
Sleep(500);
//--- thay đổi khung thời gian của biểu đồ
if(!ObjectChartSetSymbolAndPeriod(0,InpName,InpSymbol,PERIOD_M1))
return;
ChartRedraw();
//--- trì hoãn ba giây
Sleep(3000);
//--- xóa đối tượng
ObjectChartDelete(0,InpName);
ChartRedraw();
//--- đợi 1 giây
Sleep(1000);
//---
}