OBJ_TEXT
Đối tượng Văn bản.
Ghi chú
Vị trí điểm neo so với văn bản có thể được chọn từ liệt kê ENUM_ANCHOR_POINT. Bạn cũng có thể thay đổi góc nghiêng của văn bản bằng thuộc tính OBJPROP_ANGLE.
Ví dụ
Script sau tạo ra một số đối tượng Văn bản trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo đối tượng đồ họa \"Text\"."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpFont="Arial"; // Phông chữ
input int InpFontSize=10; // Kích thước phông chữ
input color InpColor=clrRed; // Màu sắc
input double InpAngle=90.0; // Góc nghiêng tính bằng độ
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_LEFT; // Loại điểm neo
input bool InpBack=false; // Đối tượng ở nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đối tượng Văn bản |
//+------------------------------------------------------------------+
bool TextCreate(const long chart_ID=0, // ID biểu đồ
const string name="Text", // Tên đối tượng
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian điểm neo
double price=0, // Giá điểm neo
const string text="Text", // Nội dung văn bản
const string font="Arial", // Phông chữ
const int font_size=10, // Kích thước phông chữ
const color clr=clrRed, // Màu sắc
const double angle=0.0, // Góc nghiêng văn bản
const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // Loại điểm neo
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeTextEmptyPoint(time,price);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo đối tượng Văn bản
if(!ObjectCreate(chart_ID,name,OBJ_TEXT,sub_window,time,price))
{
Print(__FUNCTION__,
": không thể tạo đối tượng \"Text\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập nội dung văn bản
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- thiết lập phông chữ văn bản
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- thiết lập kích thước phông chữ
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- thiết lập góc nghiêng của văn bản
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- thiết lập loại điểm neo
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- thiết lập màu sắc
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển đối tượng bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo |
//+------------------------------------------------------------------+
bool TextMove(const long chart_ID=0, // ID biểu đồ
const string name="Text", // Tên đối tượng
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi nội dung văn bản của đối tượng |
//+------------------------------------------------------------------+
bool TextChange(const long chart_ID=0, // ID biểu đồ
const string name="Text", // Tên đối tượng
const string text="Text") // Văn bản
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi nội dung văn bản của đối tượng
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": không thể thay đổi văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đối tượng Văn bản |
//+------------------------------------------------------------------+
bool TextDelete(const long chart_ID=0, // ID biểu đồ
const string name="Text") // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đối tượng
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đối tượng \"Text\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị điểm neo và thiết lập giá trị mặc định |
//| cho các điểm trống |
//+------------------------------------------------------------------+
void ChangeTextEmptyPoint(datetime &time,double &price)
{
//--- nếu thời gian của điểm không được thiết lập, nó sẽ ở trên thanh hiện tại
if(!time)
time=TimeCurrent();
//--- nếu giá của điểm không được thiết lập, nó sẽ có giá trị Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // mảng lưu trữ ngày của các thanh hiển thị
double low[]; // mảng lưu trữ giá Low của các thanh hiển thị
double high[]; // mảng lưu trữ giá High của các thanh hiển thị
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- phân bổ bộ nhớ
ArrayResize(date,bars);
ArrayResize(low,bars);
ArrayResize(high,bars);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá Low
if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
{
Print("Không thể sao chép giá trị giá Low! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá High
if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
{
Print("Không thể sao chép giá trị giá High! Mã lỗi = ",GetLastError());
return;
}
//--- xác định tần suất hiển thị văn bản
int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- xác định bước
int step=1;
switch(scale)
{
case 0:
step=12;
break;
case 1:
step=6;
break;
case 2:
step=4;
break;
case 3:
step=2;
break;
}
//--- tạo văn bản cho giá trị của các thanh High và Low (có khoảng cách)
for(int i=0;i<bars;i+=step)
{
//--- tạo các văn bản
if(!TextCreate(0,"TextHigh_"+(string)i,0,date[i],high[i],DoubleToString(high[i],5),InpFont,InpFontSize,
InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
if(!TextCreate(0,"TextLow_"+(string)i,0,date[i],low[i],DoubleToString(low[i],5),InpFont,InpFontSize,
InpColor,-InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- nửa giây trì hoãn
Sleep(500);
//--- xóa các văn bản
for(int i=0;i<bars;i+=step)
{
if(!TextDelete(0,"TextHigh_"+(string)i))
return;
if(!TextDelete(0,"TextLow_"+(string)i))
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//---
}