OBJ_ARROW_CHECK
Ký hiệu "Đánh dấu".
Ghi chú
Vị trí điểm neo so với ký hiệu có thể được chọn từ bảng liệt kê ENUM_ARROW_ANCHOR.
Các ký hiệu lớn (hơn 5) chỉ có thể được tạo bằng cách thiết lập giá trị phù hợp của thuộc tính OBJPROP_WIDTH khi viết mã trong MetaEditor.
Ví dụ
Script sau tạo và di chuyển ký hiệu "Đánh dấu" trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ ký hiệu \"Đánh dấu\"."
#property description "Tọa độ điểm neo được thiết lập theo"
#property description "phần trăm của kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="ArrowCheck"; // Tên ký hiệu
input int InpDate=10; // Ngày điểm neo tính bằng %
input int InpPrice=50; // Giá điểm neo tính bằng %
input ENUM_ARROW_ANCHOR InpAnchor=ANCHOR_TOP; // Loại điểm neo
input color InpColor=clrRed; // Màu ký hiệu
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // Kiểu đường viền
input int InpWidth=5; // Kích thước ký hiệu
input bool InpBack=false; // Ký hiệu ở nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo ký hiệu Đánh dấu |
//+------------------------------------------------------------------+
bool ArrowCheckCreate(const long chart_ID=0, // ID biểu đồ
const string name="ArrowCheck", // Tên ký hiệu
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian điểm neo
double price=0, // Giá điểm neo
const ENUM_ARROW_ANCHOR anchor=ANCHOR_BOTTOM, // Loại điểm neo
const color clr=clrRed, // Màu ký hiệu
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường viền
const int width=3, // Kích thước ký hiệu
const bool back=false, // Ở nền
const bool selection=true, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeArrowEmptyPoint(time,price);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo ký hiệu
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_CHECK,sub_window,time,price))
{
Print(__FUNCTION__,
": không thể tạo ký hiệu \"Đánh dấu\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập loại điểm neo
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- thiết lập màu ký hiệu
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập kích thước ký hiệu
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển ký hiệu bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được làm nổi bật và di chuyển theo mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép làm nổi bật và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo |
//+------------------------------------------------------------------+
bool ArrowCheckMove(const long chart_ID=0, // ID biểu đồ
const string name="ArrowCheck", // Tên đối tượng
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi loại điểm neo của ký hiệu Đánh dấu |
//+------------------------------------------------------------------+
bool ArrowCheckAnchorChange(const long chart_ID=0, // ID biểu đồ
const string name="ArrowCheck", // Tên đối tượng
const ENUM_ARROW_ANCHOR anchor=ANCHOR_TOP) // Vị trí điểm neo
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi loại điểm neo
if(!ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor))
{
Print(__FUNCTION__,
": không thể thay đổi loại điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa ký hiệu Đánh dấu |
//+------------------------------------------------------------------+
bool ArrowCheckDelete(const long chart_ID=0, // ID biểu đồ
const string name="ArrowCheck") // Tên ký hiệu
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa ký hiệu
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa ký hiệu \"Đánh dấu\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị điểm neo và thiết lập giá trị mặc định |
//| cho các điểm trống |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- nếu thời gian của điểm không được thiết lập, nó sẽ ở trên thanh hiện tại
if(!time)
time=TimeCurrent();
//--- nếu giá của điểm không được thiết lập, nó sẽ có giá trị Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Lỗi! Giá trị không chính xác của các tham số đầu vào!");
return;
}
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để thiết lập và thay đổi tọa độ điểm neo của ký hiệu
datetime date[];
double price[];
//--- phân bổ bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ ký hiệu
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- tạo ký hiệu Đánh dấu trên biểu đồ
if(!ArrowCheckCreate(0,InpName,0,date[d],price[p],InpAnchor,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển điểm neo và thay đổi vị trí của nó so với ký hiệu
//--- bộ đếm vòng lặp
int h_steps=bars*2/5;
//--- di chuyển điểm neo
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d<bars-1)
d+=1;
//--- di chuyển điểm
if(!ArrowCheckMove(0,InpName,date[d],price[p]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.025 giây trì hoãn
Sleep(25);
}
//--- thay đổi vị trí điểm neo so với ký hiệu
ArrowCheckAnchorChange(0,InpName,ANCHOR_BOTTOM);
//--- vẽ lại biểu đồ
ChartRedraw();
//--- bộ đếm vòng lặp
h_steps=bars*2/5;
//--- di chuyển điểm neo
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d<bars-1)
d+=1;
//--- di chuyển điểm
if(!ArrowCheckMove(0,InpName,date[d],price[p]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.025 giây trì hoãn
Sleep(25);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa ký hiệu khỏi biểu đồ
ArrowCheckDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}