OBJ_PITCHFORK
Chĩa ba Andrews.
Ghi chú
Đối với Chĩa ba Andrews, có thể chỉ định chế độ tiếp tục hiển thị của nó sang bên phải và/hoặc bên trái (thuộc tính OBJPROP_RAY_RIGHT và OBJPROP_RAY_LEFT tương ứng).
Bạn cũng có thể chỉ định số lượng mức đường, giá trị của chúng và màu sắc.
Ví dụ
Script sau đây tạo và di chuyển Chĩa ba Andrews trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên bản trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Chĩa ba Andrews\"."
#property description "Tọa độ điểm neo được đặt theo phần trăm của"
#property description "kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Pitchfork"; // Tên chĩa ba
input int InpDate1=14; // Ngày của điểm thứ nhất, %
input int InpPrice1=40; // Giá của điểm thứ nhất, %
input int InpDate2=18; // Ngày của điểm thứ hai, %
input int InpPrice2=50; // Giá của điểm thứ hai, %
input int InpDate3=18; // Ngày của điểm thứ ba, %
input int InpPrice3=30; // Giá của điểm thứ ba, %
input color InpColor=clrRed; // Màu chĩa ba
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // Kiểu đường của chĩa ba
input int InpWidth=1; // Độ rộng đường của chĩa ba
input bool InpBack=false; // Chĩa ba nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpRayLeft=false; // Tiếp tục chĩa ba sang trái
input bool InpRayRight=false; // Tiếp tục chĩa ba sang phải
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo Chĩa ba Andrews theo tọa độ đã cho |
//+------------------------------------------------------------------+
bool PitchforkCreate(const long chart_ID=0, // ID biểu đồ
const string name="Pitchfork", // Tên chĩa ba
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
double price1=0, // Giá điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
double price2=0, // Giá điểm thứ hai
datetime time3=0, // Thời gian điểm thứ ba
double price3=0, // Giá điểm thứ ba
const color clr=clrRed, // Màu của các đường chĩa ba
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu của các đường chĩa ba
const int width=1, // Độ rộng của các đường chĩa ba
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool ray_left=false, // Tiếp tục chĩa ba sang trái
const bool ray_right=false, // Tiếp tục chĩa ba sang phải
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- đặt tọa độ các điểm neo nếu chúng chưa được đặt
ChangeChannelEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo Chĩa ba Andrews theo tọa độ đã cho
if(!ObjectCreate(chart_ID,name,OBJ_PITCHFORK,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": không thể tạo \"Chĩa ba Andrews\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- đặt màu
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ tô sáng chĩa ba để di chuyển
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị chĩa ba sang trái
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị chĩa ba sang phải
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Đặt số lượng mức và tham số của Chĩa ba Andrews |
//+------------------------------------------------------------------+
bool PitchforkLevelsSet(int levels, // Số lượng đường mức
double &values[], // Giá trị của các đường mức
color &colors[], // Màu của các đường mức
ENUM_LINE_STYLE &styles[], // Kiểu của các đường mức
int &widths[], // Độ rộng của các đường mức
const long chart_ID=0, // ID biểu đồ
const string name="Pitchfork") // Tên chĩa ba
{
//--- kiểm tra kích thước mảng
if(levels!=ArraySize(colors) || levels!=ArraySize(styles) ||
levels!=ArraySize(widths) || levels!=ArraySize(widths))
{
Print(__FUNCTION__,": độ dài mảng không tương ứng với số lượng mức, lỗi!");
return(false);
}
//--- đặt số lượng mức
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELS,levels);
//--- đặt thuộc tính của các mức trong vòng lặp
for(int i=0;i<levels;i++)
{
//--- giá trị mức
ObjectSetDouble(chart_ID,name,OBJPROP_LEVELVALUE,i,values[i]);
//--- màu mức
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELCOLOR,i,colors[i]);
//--- kiểu mức
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELSTYLE,i,styles[i]);
//--- độ rộng mức
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELWIDTH,i,widths[i]);
//--- mô tả mức
ObjectSetString(chart_ID,name,OBJPROP_LEVELTEXT,i,DoubleToString(100*values[i],1));
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo của Chĩa ba Andrews |
//+------------------------------------------------------------------+
bool PitchforkPointChange(const long chart_ID=0, // ID biểu đồ
const string name="Pitchfork", // Tên kênh
const int point_index=0, // Chỉ số điểm neo
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được đặt, di chuyển nó tới thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa Chĩa ba Andrews khỏi biểu đồ |
//+------------------------------------------------------------------+
bool PitchforkDelete(const long chart_ID=0, // ID biểu đồ
const string name="Pitchfork") // Tên kênh
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa chĩa ba
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa \"Chĩa ba Andrews\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+----------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của Chĩa ba Andrews và đặt mặc định|
//| cho những điểm trống |
//+----------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,double &price1,datetime &time2,
double &price2,datetime &time3,double &price3)
{
//--- nếu thời gian của điểm thứ hai (phía trên bên phải) không được đặt, nó sẽ nằm trên thanh hiện tại
if(!time2)
time2=TimeCurrent();
//--- nếu giá của điểm thứ hai không được đặt, nó sẽ có giá trị Bid
if(!price2)
price2=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- nếu thời gian của điểm thứ nhất (bên trái) không được đặt, nó nằm cách 9 thanh về bên trái từ điểm thứ hai
if(!time1)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- đặt điểm thứ nhất cách 9 thanh về bên trái từ điểm thứ hai
time1=temp[0];
}
//--- nếu giá của điểm thứ nhất không được đặt, di chuyển nó xuống 200 điểm dưới điểm thứ hai
if(!price1)
price1=price2-200*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- nếu thời gian của điểm thứ ba không được đặt, nó trùng với thời gian của điểm thứ hai
if(!time3)
time3=time2;
//--- nếu giá của điểm thứ ba không được đặt, di chuyển nó xuống 200 điểm dưới điểm thứ nhất
if(!price3)
price3=price1-200*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ các điểm neo của Chĩa ba Andrews
datetime date[];
double price[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ Chĩa ba Andrews
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- tạo chĩa ba
if(!PitchforkCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển các điểm neo của chĩa ba
//--- bộ đếm vòng lặp
int v_steps=accuracy/10;
//--- di chuyển điểm neo thứ nhất
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p1>1)
p1-=1;
//--- di chuyển điểm
if(!PitchforkPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
int h_steps=bars/8;
//--- di chuyển điểm neo thứ ba
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d3<bars-1)
d3+=1;
//--- di chuyển điểm
if(!PitchforkPointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
v_steps=accuracy/10;
//--- di chuyển điểm neo thứ hai
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p2>1)
p2-=1;
//--- di chuyển điểm
if(!PitchforkPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa chĩa ba khỏi biểu đồ
PitchforkDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}