OBJ_CYCLES
Đường Chu Kỳ.
Ghi chú
Khoảng cách giữa các đường được xác định bởi tọa độ thời gian của hai điểm neo của đối tượng.
Ví dụ
Script sau tạo và di chuyển các đường chu kỳ trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên bản trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo các đường chu kỳ trên biểu đồ."
#property description "Tọa độ điểm neo được đặt theo phần trăm"
#property description "phần trăm kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName=`Cycles`; // Tên đối tượng
input int InpDate1=10; // Ngày của điểm thứ nhất, %
input int InpPrice1=45; // Giá của điểm thứ nhất, %
input int InpDate2=20; // Ngày của điểm thứ hai, %
input int InpPrice2=55; // Giá của điểm thứ hai, %
input color InpColor=clrRed; // Màu của các đường chu kỳ
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // Kiểu của các đường chu kỳ
input int InpWidth=1; // Độ rộng của các đường chu kỳ
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo các đường chu kỳ |
//+------------------------------------------------------------------+
bool CyclesCreate(const long chart_ID=0, // ID biểu đồ
const string name=`Cycles`, // Tên đối tượng
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
double price1=0, // Giá điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
double price2=0, // Giá điểm thứ hai
const color clr=clrRed, // Màu của các đường chu kỳ
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu của các đường chu kỳ
const int width=1, // Độ rộng của các đường chu kỳ
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- đặt tọa độ các điểm neo nếu chúng chưa được đặt
ChangeCyclesEmptyPoints(time1,price1,time2,price2);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo các đường chu kỳ theo tọa độ đã cho
if(!ObjectCreate(chart_ID,name,OBJ_CYCLES,sub_window,time1,price1,time2,price2))
{
Print(__FUNCTION__,
`: không thể tạo các đường chu kỳ! Mã lỗi = `,GetLastError());
return(false);
}
//--- đặt màu của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu hiển thị của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển các đường bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo |
//+------------------------------------------------------------------+
bool CyclesPointChange(const long chart_ID=0, // ID biểu đồ
const string name=`Cycles`, // Tên đối tượng
const int point_index=0, // Chỉ số điểm neo
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được đặt, di chuyển nó tới thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
`: không thể di chuyển điểm neo! Mã lỗi = `,GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa các đường chu kỳ |
//+------------------------------------------------------------------+
bool CyclesDelete(const long chart_ID=0, // ID biểu đồ
const string name=`Cycles`) // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa các đường chu kỳ
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
`: không thể xóa các đường chu kỳ! Mã lỗi = `,GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của đường chu kỳ và đặt giá trị mặc định cho những điểm trống |
//+------------------------------------------------------------------+
void ChangeCyclesEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- nếu thời gian của điểm thứ nhất không được đặt, nó sẽ nằm trên thanh hiện tại
if(!time1)
time1=TimeCurrent();
//--- nếu giá của điểm thứ nhất không được đặt, nó sẽ có giá trị Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- nếu thời gian của điểm thứ hai không được đặt, nó sẽ cách 9 thanh về bên trái từ điểm thứ nhất
if(!time2)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- đặt điểm thứ hai cách 9 thanh về bên trái từ điểm thứ nhất
time2=temp[0];
}
//--- nếu giá của điểm thứ hai không được đặt, nó sẽ bằng giá của điểm thứ nhất
if(!price2)
price2=price1;
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
{
Print(`Lỗi! Giá trị tham số đầu vào không đúng!`);
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ các điểm neo của các đường chu kỳ
datetime date[];
double price[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print(`Không thể sao chép giá trị thời gian! Mã lỗi = `,GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ các đường chu kỳ
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
//--- tạo đường xu hướng
if(!CyclesCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển các điểm neo
//--- bộ đếm vòng lặp
int h_steps=bars/5;
//--- di chuyển điểm neo thứ hai
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d2<bars-1)
d2+=1;
//--- di chuyển điểm
if(!CyclesPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
h_steps=bars/4;
//--- di chuyển điểm neo thứ nhất
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d1<bars-1)
d1+=1;
//--- di chuyển điểm
if(!CyclesPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa đối tượng khỏi biểu đồ
CyclesDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}