OBJ_LABEL
Đối tượng Nhãn.
Ghi chú
Vị trí điểm neo so với nhãn có thể được chọn từ liệt kê ENUM_ANCHOR_POINT. Tọa độ điểm neo được thiết lập bằng pixel.
Bạn cũng có thể chọn góc neo của nhãn văn bản từ liệt kê ENUM_BASE_CORNER.
Ví dụ
Script sau tạo và di chuyển đối tượng Chỉnh sửa trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo đối tượng đồ họa \"Label\"."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Label"; // Tên nhãn
input int InpX=150; // Khoảng cách trục X
input int InpY=150; // Khoảng cách trục Y
input string InpFont="Arial"; // Phông chữ
input int InpFontSize=14; // Kích thước phông chữ
input color InpColor=clrRed; // Màu sắc
input double InpAngle=0.0; // Góc nghiêng tính bằng độ
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_CENTER; // Loại điểm neo
input bool InpBack=false; // Đối tượng ở nền
input bool InpSelection=true; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo nhãn văn bản |
//+------------------------------------------------------------------+
bool LabelCreate(const long chart_ID=0, // ID biểu đồ
const string name="Label", // Tên nhãn
const int sub_window=0, // Chỉ số cửa sổ phụ
const int x=0, // Tọa độ X
const int y=0, // Tọa độ Y
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // Góc biểu đồ để neo
const string text="Label", // Văn bản
const string font="Arial", // Phông chữ
const int font_size=10, // Kích thước phông chữ
const color clr=clrRed, // Màu sắc
const double angle=0.0, // Góc nghiêng văn bản
const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // Loại điểm neo
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo nhãn văn bản
if(!ObjectCreate(chart_ID,name,OBJ_LABEL,sub_window,0,0))
{
Print(__FUNCTION__,
": không thể tạo nhãn văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập tọa độ nhãn
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- thiết lập góc biểu đồ, tương ứng với tọa độ điểm
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- thiết lập văn bản
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- thiết lập phông chữ văn bản
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- thiết lập kích thước phông chữ
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- thiết lập góc nghiêng của văn bản
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- thiết lập loại điểm neo
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- thiết lập màu sắc
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển nhãn văn bản |
//+------------------------------------------------------------------+
bool LabelMove(const long chart_ID=0, // ID biểu đồ
const string name="Label", // Tên nhãn
const int x=0, // Tọa độ X
const int y=0) // Tọa độ Y
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển nhãn văn bản
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ X của nhãn! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ Y của nhãn! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi góc neo của biểu đồ cho nhãn |
//+------------------------------------------------------------------+
bool LabelChangeCorner(const long chart_ID=0, // ID biểu đồ
const string name="Label", // Tên nhãn
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER) // Góc biểu đồ để neo
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi góc neo
if(!ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner))
{
Print(__FUNCTION__,
": không thể thay đổi góc neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi văn bản của nhãn |
//+------------------------------------------------------------------+
bool LabelTextChange(const long chart_ID=0, // ID biểu đồ
const string name="Label", // Tên đối tượng
const string text="Text") // Văn bản
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi văn bản của đối tượng
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": không thể thay đổi văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa nhãn văn bản |
//+------------------------------------------------------------------+
bool LabelDelete(const long chart_ID=0, // ID biểu đồ
const string name="Label") // Tên nhãn
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nhãn
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa nhãn văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- lưu tọa độ của nhãn vào các biến cục bộ
int x=InpX;
int y=InpY;
//--- kích thước cửa sổ biểu đồ
long x_distance;
long y_distance;
//--- thiết lập kích thước cửa sổ
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Không thể lấy chiều rộng biểu đồ! Mã lỗi = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Không thể lấy chiều cao biểu đồ! Mã lỗi = ",GetLastError());
return;
}
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpX<0 || InpX>x_distance-1 || InpY<0 || InpY>y_distance-1)
{
Print("Lỗi! Giá trị không đúng của các tham số đầu vào!");
return;
}
//--- chuẩn bị văn bản ban đầu cho nhãn
string text;
StringConcatenate(text,"Góc trên bên trái: ",x,",",y);
//--- tạo nhãn văn bản trên biểu đồ
if(!LabelCreate(0,InpName,0,InpX,InpY,CORNER_LEFT_UPPER,text,InpFont,InpFontSize,
InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi nửa giây
ChartRedraw();
Sleep(500);
//--- di chuyển nhãn và thay đổi văn bản của nó đồng thời
//--- số lần lặp theo trục
int h_steps=(int)(x_distance/2-InpX);
int v_steps=(int)(y_distance/2-InpY);
//--- di chuyển nhãn xuống dưới
for(int i=0;i<v_steps;i++)
{
//--- thay đổi tọa độ
y+=2;
//--- di chuyển nhãn và thay đổi văn bản của nó
MoveAndTextChange(x,y,"Góc trên bên trái: ");
}
//--- nửa giây trì hoãn
Sleep(500);
//--- di chuyển nhãn sang phải
for(int i=0;i<h_steps;i++)
{
//--- thay đổi tọa độ
x+=2;
//--- di chuyển nhãn và thay đổi văn bản của nó
MoveAndTextChange(x,y,"Góc trên bên trái: ");
}
//--- nửa giây trì hoãn
Sleep(500);
//--- di chuyển nhãn lên trên
for(int i=0;i<v_steps;i++)
{
//--- thay đổi tọa độ
y-=2;
//--- di chuyển nhãn và thay đổi văn bản của nó
MoveAndTextChange(x,y,"Góc trên bên trái: ");
}
//--- nửa giây trì hoãn
Sleep(500);
//--- di chuyển nhãn sang trái
for(int i=0;i<h_steps;i++)
{
//--- thay đổi tọa độ
x-=2;
//--- di chuyển nhãn và thay đổi văn bản của nó
MoveAndTextChange(x,y,"Góc trên bên trái: ");
}
//--- nửa giây trì hoãn
Sleep(500);
//--- bây giờ, di chuyển điểm bằng cách thay đổi góc neo
//--- di chuyển đến góc dưới bên trái
if(!LabelChangeCorner(0,InpName,CORNER_LEFT_LOWER))
return;
//--- thay đổi văn bản của nhãn
StringConcatenate(text,"Góc dưới bên trái: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- vẽ lại biểu đồ và đợi hai giây
ChartRedraw();
Sleep(2000);
//--- di chuyển đến góc dưới bên phải
if(!LabelChangeCorner(0,InpName,CORNER_RIGHT_LOWER))
return;
//--- thay đổi văn bản của nhãn
StringConcatenate(text,"Góc dưới bên phải: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- vẽ lại biểu đồ và đợi hai giây
ChartRedraw();
Sleep(2000);
//--- di chuyển đến góc trên bên phải
if(!LabelChangeCorner(0,InpName,CORNER_RIGHT_UPPER))
return;
//--- thay đổi văn bản của nhãn
StringConcatenate(text,"Góc trên bên phải: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- vẽ lại biểu đồ và đợi hai giây
ChartRedraw();
Sleep(2000);
//--- di chuyển đến góc trên bên trái
if(!LabelChangeCorner(0,InpName,CORNER_LEFT_UPPER))
return;
//--- thay đổi văn bản của nhãn
StringConcatenate(text,"Góc trên bên trái: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- vẽ lại biểu đồ và đợi hai giây
ChartRedraw();
Sleep(2000);
//--- xóa nhãn
LabelDelete(0,InpName);
//--- vẽ lại biểu đồ và đợi nửa giây
ChartRedraw();
Sleep(500);
//---
}
//+------------------------------------------------------------------+
//| Hàm di chuyển đối tượng và thay đổi văn bản của nó |
//+------------------------------------------------------------------+
bool MoveAndTextChange(const int x,const int y,string text)
{
//--- di chuyển nhãn
if(!LabelMove(0,InpName,x,y))
return(false);
//--- thay đổi văn bản của nhãn
StringConcatenate(text,text,x,",",y);
if(!LabelTextChange(0,InpName,text))
return(false);
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return(false);
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.01 giây trì hoãn
Sleep(10);
//--- thoát hàm
return(true);
}