OBJ_TRIANGLE
Hình tam giác.
Ghi chú
Đối với hình tam giác, chế độ tô màu có thể được thiết lập bằng thuộc tính OBJPROP_FILL.
Ví dụ
Script sau tạo và di chuyển hình tam giác trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo hình tam giác trên biểu đồ."
#property description "Tọa độ điểm neo được thiết lập theo"
#property description "phần trăm kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Triangle"; // Tên tam giác
input int InpDate1=25; // Ngày của điểm thứ 1, %
input int InpPrice1=50; // Giá của điểm thứ 1, %
input int InpDate2=70; // Ngày của điểm thứ 2, %
input int InpPrice2=70; // Giá của điểm thứ 2, %
input int InpDate3=65; // Ngày của điểm thứ 3, %
input int InpPrice3=20; // Giá của điểm thứ 3, %
input color InpColor=clrRed; // Màu tam giác
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Kiểu đường viền tam giác
input int InpWidth=2; // Độ dày đường viền tam giác
input bool InpFill=false; // Tô màu tam giác
input bool InpBack=false; // Tam giác ở nền
input bool InpSelection=true; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo tam giác bởi các tọa độ đã cho |
//+------------------------------------------------------------------+
bool TriangleCreate(const long chart_ID=0, // ID biểu đồ
const string name="Triangle", // Tên tam giác
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
double price1=0, // Giá điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
double price2=0, // Giá điểm thứ hai
datetime time3=0, // Thời gian điểm thứ ba
double price3=0, // Giá điểm thứ ba
const color clr=clrRed, // Màu tam giác
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường viền tam giác
const int width=1, // Độ dày đường viền tam giác
const bool fill=false, // Tô màu tam giác
const bool back=false, // Ở nền
const bool selection=true, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeTriangleEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo tam giác bởi các tọa độ đã cho
if(!ObjectCreate(chart_ID,name,OBJ_TRIANGLE,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
": không thể tạo tam giác! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập màu tam giác
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền tam giác
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập độ dày đường viền tam giác
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- bật (true) hoặc tắt (false) chế độ tô màu tam giác
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ làm nổi bật tam giác để di chuyển
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được làm nổi bật và di chuyển theo mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép làm nổi bật và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho việc nhận sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo của tam giác |
//+------------------------------------------------------------------+
bool TrianglePointChange(const long chart_ID=0, // ID biểu đồ
const string name="Triangle", // Tên tam giác
const int point_index=0, // Chỉ số điểm neo
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa tam giác |
//+------------------------------------------------------------------+
bool TriangleDelete(const long chart_ID=0, // ID biểu đồ
const string name="Triangle") // Tên tam giác
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa tam giác
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa tam giác! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của tam giác và thiết lập |
//| giá trị mặc định cho các điểm trống |
//+------------------------------------------------------------------+
void ChangeTriangleEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3)
{
//--- nếu thời gian của điểm thứ nhất không được thiết lập, nó sẽ ở trên thanh hiện tại
if(!time1)
time1=TimeCurrent();
//--- nếu giá của điểm thứ nhất không được thiết lập, nó sẽ có giá trị Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- nếu thời gian của điểm thứ hai không được thiết lập, nó nằm cách 9 thanh bên trái từ điểm thứ nhất
if(!time2)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- thiết lập điểm thứ hai cách 9 thanh bên trái từ điểm thứ nhất
time2=temp[0];
}
//--- nếu giá của điểm thứ hai không được thiết lập, di chuyển nó thấp hơn 300 điểm so với điểm thứ nhất
if(!price2)
price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- nếu thời gian của điểm thứ ba không được thiết lập, nó trùng với ngày của điểm thứ hai
if(!time3)
time3=time2;
//--- nếu giá của điểm thứ ba không được thiết lập, nó bằng với giá của điểm thứ nhất
if(!price3)
price3=price1;
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Lỗi! Giá trị không chính xác của các tham số đầu vào!");
return;
}
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để thiết lập và thay đổi tọa độ điểm neo của tam giác
datetime date[];
double price[];
//--- phân bổ bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ tam giác
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- tạo tam giác
if(!TriangleCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển các điểm neo của tam giác
//--- bộ đếm vòng lặp
int v_steps=accuracy*3/10;
//--- di chuyển điểm neo thứ nhất
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p1>1)
p1-=1;
//--- di chuyển điểm
if(!TrianglePointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
int h_steps=bars*9/20-1;
//--- di chuyển điểm neo thứ hai
for(int i=0;i<h_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(d2>1)
d2-=1;
//--- di chuyển điểm
if(!TrianglePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
v_steps=accuracy/4;
//--- di chuyển điểm neo thứ ba
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p3<accuracy-1)
p3+=1;
//--- di chuyển điểm
if(!TrianglePointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa tam giác khỏi biểu đồ
TriangleDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}