OBJ_BUTTON
Đối tượng Nút.
Ghi chú
Tọa độ điểm neo được thiết lập bằng pixel. Bạn có thể chọn góc neo của nút từ ENUM_BASE_CORNER.
Ví dụ
Script sau tạo và di chuyển đối tượng Nút trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo nút trên biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Button"; // Tên nút
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // Góc biểu đồ để neo
input string InpFont="Arial"; // Phông chữ
input int InpFontSize=14; // Kích thước phông chữ
input color InpColor=clrBlack; // Màu chữ
input color InpBackColor=C'236,233,216'; // Màu nền
input color InpBorderColor=clrNONE; // Màu viền
input bool InpState=false; // Nhấn/Thả
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo nút |
//+------------------------------------------------------------------+
bool ButtonCreate(const long chart_ID=0, // ID biểu đồ
const string name="Button", // Tên nút
const int sub_window=0, // Chỉ số cửa sổ phụ
const int x=0, // Tọa độ X
const int y=0, // Tọa độ Y
const int width=50, // Chiều rộng nút
const int height=18, // Chiều cao nút
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // Góc biểu đồ để neo
const string text="Button", // Văn bản
const string font="Arial", // Phông chữ
const int font_size=10, // Kích thước phông chữ
const color clr=clrBlack, // Màu chữ
const color back_clr=C'236,233,216', // Màu nền
const color border_clr=clrNONE, // Màu viền
const bool state=false, // Nhấn/Thả
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo nút
if(!ObjectCreate(chart_ID,name,OBJ_BUTTON,sub_window,0,0))
{
Print(__FUNCTION__,
": không thể tạo nút! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập tọa độ nút
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- thiết lập kích thước nút
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- thiết lập góc biểu đồ, tương ứng với tọa độ điểm
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- thiết lập văn bản
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- thiết lập phông chữ
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- thiết lập kích thước phông chữ
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- thiết lập màu chữ
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập màu nền
ObjectSetInteger(chart_ID,name,OBJPROP_BGCOLOR,back_clr);
//--- thiết lập màu viền
ObjectSetInteger(chart_ID,name,OBJPROP_BORDER_COLOR,border_clr);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- thiết lập trạng thái nút
ObjectSetInteger(chart_ID,name,OBJPROP_STATE,state);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nút bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển nút |
//+------------------------------------------------------------------+
bool ButtonMove(const long chart_ID=0, // ID biểu đồ
const string name="Button", // Tên nút
const int x=0, // Tọa độ X
const int y=0) // Tọa độ Y
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển nút
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ X của nút! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ Y của nút! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi kích thước nút |
//+------------------------------------------------------------------+
bool ButtonChangeSize(const long chart_ID=0, // ID biểu đồ
const string name="Button", // Tên nút
const int width=50, // Chiều rộng nút
const int height=18) // Chiều cao nút
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi kích thước nút
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": không thể thay đổi chiều rộng nút! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": không thể thay đổi chiều cao nút! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi góc neo của biểu đồ cho nút |
//+------------------------------------------------------------------+
bool ButtonChangeCorner(const long chart_ID=0, // ID biểu đồ
const string name="Button", // Tên nút
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER) // Góc biểu đồ để neo
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi góc neo
if(!ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner))
{
Print(__FUNCTION__,
": không thể thay đổi góc neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi văn bản của nút |
//+------------------------------------------------------------------+
bool ButtonTextChange(const long chart_ID=0, // ID biểu đồ
const string name="Button", // Tên nút
const string text="Text") // Văn bản
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi văn bản của đối tượng
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": không thể thay đổi văn bản! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa nút |
//+------------------------------------------------------------------+
bool ButtonDelete(const long chart_ID=0, // ID biểu đồ
const string name="Button") // Tên nút
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nút
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa nút! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kích thước cửa sổ biểu đồ
long x_distance;
long y_distance;
//--- thiết lập kích thước cửa sổ
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Không thể lấy chiều rộng biểu đồ! Mã lỗi = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Không thể lấy chiều cao biểu đồ! Mã lỗi = ",GetLastError());
return;
}
//--- xác định bước thay đổi kích thước nút
int x_step=(int)x_distance/32;
int y_step=(int)y_distance/32;
//--- thiết lập tọa độ và kích thước của nút
int x=(int)x_distance/32;
int y=(int)y_distance/32;
int x_size=(int)x_distance*15/16;
int y_size=(int)y_distance*15/16;
//--- tạo nút
if(!ButtonCreate(0,InpName,0,x,y,x_size,y_size,InpCorner,"Press",InpFont,InpFontSize,
InpColor,InpBackColor,InpBorderColor,InpState,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ
ChartRedraw();
//--- thu nhỏ nút trong vòng lặp
int i=0;
while(i<13)
{
//--- trì hoãn nửa giây
Sleep(500);
//--- chuyển nút sang trạng thái nhấn
ObjectSetInteger(0,InpName,OBJPROP_STATE,true);
//--- vẽ lại biểu đồ và đợi 0.2 giây
ChartRedraw();
Sleep(200);
//--- xác định lại tọa độ và kích thước nút
x+=x_step;
y+=y_step;
x_size-=x_step*2;
y_size-=y_step*2;
//--- thu nhỏ nút
ButtonMove(0,InpName,x,y);
ButtonChangeSize(0,InpName,x_size,y_size);
//--- đưa nút trở lại trạng thái thả
ObjectSetInteger(0,InpName,OBJPROP_STATE,false);
//--- vẽ lại biểu đồ
ChartRedraw();
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- tăng biến đếm vòng lặp
i++;
}
//--- trì hoãn nửa giây
Sleep(500);
//--- xóa nút
ButtonDelete(0,InpName);
ChartRedraw();
//--- đợi 1 giây
Sleep(1000);
//---
}