OBJ_TRENDBYANGLE
Đường Xu Hướng Theo Góc.
Ghi chú
Đối với Đường Xu Hướng Theo Góc, có thể chỉ định chế độ tiếp tục hiển thị sang bên phải và/hoặc bên trái (thuộc tính OBJPROP_RAY_RIGHT và OBJPROP_RAY_LEFT tương ứng).
Cả góc độ và tọa độ của điểm neo thứ hai đều có thể được sử dụng để đặt độ dốc của đường.
Ví dụ
Script sau tạo và di chuyển đường xu hướng trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên bản" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Đường Xu Hướng Theo Góc\"."
#property description "Tọa độ điểm neo được đặt theo phần trăm kích thước"
#property description "của cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Trend"; // Tên đường
input int InpDate1=50; // Ngày của điểm thứ nhất, %
input int InpPrice1=75; // Giá của điểm thứ nhất, %
input int InpAngle=0; // Góc độ dốc của đường
input color InpColor=clrRed; // Màu đường
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Kiểu đường
input int InpWidth=2; // Độ rộng đường
input bool InpBack=false; // Đường nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpRayLeft=false; // Tiếp tục đường sang trái
input bool InpRayRight=true; // Tiếp tục đường sang phải
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đường xu hướng theo góc |
//+------------------------------------------------------------------+
bool TrendByAngleCreate(const long chart_ID=0, // ID biểu đồ
const string name="TrendLine", // Tên đường
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian điểm
double price=0, // Giá điểm
const double angle=45.0, // Góc độ dốc
const color clr=clrRed, // Màu đường
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường
const int width=1, // Độ rộng đường
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool ray_left=false, // Tiếp tục sang trái
const bool ray_right=true, // Tiếp tục sang phải
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- tạo điểm thứ hai để hỗ trợ kéo đường xu hướng bằng chuột
datetime time2=0;
double price2=0;
//--- đặt tọa độ điểm neo nếu chưa được đặt
ChangeTrendEmptyPoints(time,price,time2,price2);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo đường xu hướng bằng 2 điểm
if(!ObjectCreate(chart_ID,name,OBJ_TRENDBYANGLE,sub_window,time,price,time2,price2))
{
Print(__FUNCTION__,
": không thể tạo đường xu hướng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thay đổi góc độ dốc của đường xu hướng; khi thay đổi góc, tọa độ của điểm thứ hai
//--- sẽ tự động được xác định lại theo giá trị góc mới
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- đặt màu đường
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển đường bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị đường sang trái
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị đường sang phải
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi tọa độ điểm neo của đường xu hướng |
//+------------------------------------------------------------------+
bool TrendPointChange(const long chart_ID=0, // ID biểu đồ
const string name="TrendLine", // Tên đường
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được đặt, di chuyển nó tới thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo của đường xu hướng
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi góc độ dốc của đường xu hướng |
//+------------------------------------------------------------------+
bool TrendAngleChange(const long chart_ID=0, // ID biểu đồ
const string name="TrendLine", // Tên đường xu hướng
const double angle=45) // Góc độ dốc của đường xu hướng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi góc độ dốc của đường xu hướng
if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
{
Print(__FUNCTION__,
": không thể thay đổi góc độ dốc của đường! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đường xu hướng khỏi biểu đồ |
//+------------------------------------------------------------------+
bool TrendDelete(const long chart_ID=0, // ID biểu đồ
const string name="TrendLine") // Tên đường
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đường xu hướng
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đường xu hướng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của đường xu hướng và đặt giá trị mặc định cho những điểm trống |
//+------------------------------------------------------------------+
void ChangeTrendEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- nếu thời gian của điểm thứ nhất không được đặt, nó sẽ nằm trên thanh hiện tại
if(!time1)
time1=TimeCurrent();
//--- nếu giá của điểm thứ nhất không được đặt, nó sẽ có giá trị Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt tọa độ của điểm thứ hai, điểm phụ trợ
//--- điểm thứ hai sẽ cách 9 thanh về bên trái và có cùng giá
datetime second_point_time[10];
CopyTime(Symbol(),Period(),time1,10,second_point_time);
time2=second_point_time[0];
price2=price1;
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ các điểm neo của đường
datetime date[];
double price[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ đường
int d1=InpDate1*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- tạo đường xu hướng
if(!TrendByAngleCreate(0,InpName,0,date[d1],price[p1],InpAngle,InpColor,InpStyle,
InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển và xoay đường
//--- bộ đếm vòng lặp
int v_steps=accuracy/2;
//--- di chuyển điểm neo và thay đổi góc độ dốc của đường
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p1>1)
p1-=1;
//--- di chuyển điểm
if(!TrendPointChange(0,InpName,date[d1],price[p1]))
return;
if(!TrendAngleChange(0,InpName,18*(i+1)))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa khỏi biểu đồ
TrendDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}