OBJ_REGRESSION
Kênh Hồi Quy Tuyến Tính.
Ghi chú
Đối với Kênh Hồi Quy Tuyến Tính, có thể chỉ định chế độ tiếp tục hiển thị của nó sang bên phải và/hoặc bên trái (thuộc tính OBJPROP_RAY_RIGHT và OBJPROP_RAY_LEFT tương ứng). Chế độ tô màu kênh cũng có thể được thiết lập.
Ví dụ
Script sau đây tạo và di chuyển Kênh Hồi Quy Tuyến Tính trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên bản trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Kênh Hồi Quy Tuyến Tính\"."
#property description "Tọa độ điểm neo được đặt theo phần trăm của kích thước"
#property description "cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="Regression"; // Tên kênh
input int InpDate1=10; // Ngày của điểm thứ nhất, %
input int InpDate2=40; // Ngày của điểm thứ hai, %
input color InpColor=clrRed; // Màu kênh
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Kiểu đường của kênh
input int InpWidth=2; // Độ rộng đường của kênh
input bool InpFill=false; // Tô màu kênh
input bool InpBack=false; // Kênh nền
input bool InpSelection=true; // Tô sáng để di chuyển
input bool InpRayLeft=false; // Tiếp tục kênh sang trái
input bool InpRayRight=false; // Tiếp tục kênh sang phải
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo Kênh Hồi Quy Tuyến Tính theo tọa độ đã cho |
//+------------------------------------------------------------------+
bool RegressionCreate(const long chart_ID=0, // ID biểu đồ
const string name="Regression", // Tên kênh
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
const color clr=clrRed, // Màu kênh
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường của kênh
const int width=1, // Độ rộng đường của kênh
const bool fill=false, // Tô màu kênh
const bool back=false, // Ở nền
const bool selection=true, // Tô sáng để di chuyển
const bool ray_left=false, // Tiếp tục kênh sang trái
const bool ray_right=false, // Tiếp tục kênh sang phải
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Ưu tiên cho cú nhấp chuột
{
//--- đặt tọa độ các điểm neo nếu chúng chưa được đặt
ChangeRegressionEmptyPoints(time1,time2);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo một kênh theo tọa độ đã cho
if(!ObjectCreate(chart_ID,name,OBJ_REGRESSION,sub_window,time1,0,time2,0))
{
Print(__FUNCTION__,
": không thể tạo kênh hồi quy tuyến tính! Mã lỗi = ",GetLastError());
return(false);
}
//--- đặt màu kênh
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- đặt kiểu của các đường kênh
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- đặt độ rộng của các đường kênh
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- bật (true) hoặc tắt (false) chế độ tô màu kênh
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ tô sáng kênh để di chuyển
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được tô sáng và di chuyển mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép tô sáng và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị kênh sang trái
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- bật (true) hoặc tắt (false) chế độ tiếp tục hiển thị kênh sang phải
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- đặt mức độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo của kênh |
//+------------------------------------------------------------------+
bool RegressionPointChange(const long chart_ID=0, // ID biểu đồ
const string name="Channel", // Tên kênh
const int point_index=0, // Chỉ số điểm neo
datetime time=0) // Tọa độ thời gian điểm neo
{
//--- nếu thời gian điểm không được đặt, di chuyển điểm tới thanh hiện tại
if(!time)
time=TimeCurrent();
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,point_index,time,0))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa kênh khỏi biểu đồ |
//+------------------------------------------------------------------+
bool RegressionDelete(const long chart_ID=0, // ID biểu đồ
const string name="Channel") // Tên kênh
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa kênh
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa kênh! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+-------------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của kênh và đặt giá trị mặc định |
//| cho những điểm trống |
//+-------------------------------------------------------------------------+
void ChangeRegressionEmptyPoints(datetime &time1,datetime &time2)
{
//--- nếu thời gian của điểm thứ hai không được đặt, nó sẽ nằm trên thanh hiện tại
if(!time2)
time2=TimeCurrent();
//--- nếu thời gian của điểm thứ nhất không được đặt, nó nằm cách 9 thanh về bên trái từ điểm thứ hai
if(!time1)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- đặt điểm thứ nhất cách 9 thanh về bên trái từ điểm thứ hai
time1=temp[0];
}
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate1<0 || InpDate1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Lỗi! Giá trị tham số đầu vào không đúng!");
return;
}
//--- số thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để đặt và thay đổi tọa độ các điểm neo của kênh
datetime date[];
double price[];
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ kênh
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
//--- tạo kênh hồi quy tuyến tính
if(!RegressionCreate(0,InpName,0,date[d1],date[d2],InpColor,InpStyle,InpWidth,
InpFill,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển kênh theo chiều ngang sang phải
//--- bộ đếm vòng lặp
int h_steps=bars/2;
//--- di chuyển kênh
for(int i=0;i<h_steps;i++)
{
//--- sử dụng các giá trị tiếp theo
if(d1<bars-1)
d1+=1;
if(d2<bars-1)
d2+=1;
//--- di chuyển các điểm neo
if(!RegressionPointChange(0,InpName,0,date[d1]))
return;
if(!RegressionPointChange(0,InpName,1,date[d2]))
return;
//--- kiểm tra xem hoạt động của script có bị vô hiệu hóa cưỡng chế không
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa kênh khỏi biểu đồ
RegressionDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}