OBJ_EVENT

Đối tượng Sự kiện.

Ghi chú

Khi di chuột qua sự kiện, văn bản của nó sẽ xuất hiện.

Ví dụ

Script sau tạo và di chuyển đối tượng Sự kiện trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên trạng trong các ứng dụng của riêng bạn.

//--- mô tả
#property description "Script vẽ đối tượng đồ họa \"Event\"."
#property description "Ngày điểm neo được thiết lập bằng phần trăm của"
#property description "chiều rộng cửa sổ biểu đồ tính bằng thanh."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string          InpName="Event";    // Tên sự kiện
input int             InpDate=25;         // Ngày sự kiện, %
input string          InpText="Text";     // Văn bản sự kiện
input color           InpColor=clrRed;    // Màu sự kiện
input int             InpWidth=1;         // Kích thước điểm khi được làm nổi bật
input bool            InpBack=false;      // Sự kiện nền
input bool            InpSelection=false; // Làm nổi bật để di chuyển
input bool            InpHidden=true;     // Ẩn trong danh sách đối tượng
input long            InpZOrder=0;        // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đối tượng Sự kiện trên biểu đồ                               |
//+------------------------------------------------------------------+
bool EventCreate(const long            chart_ID=0,      // ID biểu đồ
                 const string          name="Event",    // Tên sự kiện
                 const int             sub_window=0,    // Chỉ số cửa sổ phụ
                 const string          text="Text",     // Văn bản sự kiện
                 datetime              time=0,          // Thời gian
                 const color           clr=clrRed,      // Màu sắc
                 const int             width=1,         // Độ rộng điểm khi được làm nổi bật
                 const bool            back=false,      // Ở nền
                 const bool            selection=false, // Làm nổi bật để di chuyển
                 const bool            hidden=true,     // Ẩn trong danh sách đối tượng
                 const long            z_order=0)       // Độ ưu tiên cho cú nhấp chuột
  {
//--- nếu thời gian không được thiết lập, tạo đối tượng trên thanh cuối cùng
   if(!time)
      time=TimeCurrent();
//--- đặt lại giá trị lỗi
   ResetLastError();
//--- tạo đối tượng Sự kiện
   if(!ObjectCreate(chart_ID,name,OBJ_EVENT,sub_window,time,0))
     {
      Print(__FUNCTION__,
            ": không thể tạo đối tượng \"Event\"! Mã lỗi = ",GetLastError());
      return(false);
     }
//--- thiết lập văn bản sự kiện
   ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- thiết lập màu sắc
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập độ rộng điểm neo nếu đối tượng được làm nổi bật
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển sự kiện bằng chuột
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
   return(true);
  }
//+------------------------------------------------------------------+
//| Thay đổi văn bản đối tượng Sự kiện                               |
//+------------------------------------------------------------------+
bool EventTextChange(const long   chart_ID=0,   // ID biểu đồ
                     const string name="Event", // Tên sự kiện
                     const string text="Text")  // Văn bản
  {
//--- đặt lại giá trị lỗi
   ResetLastError();
//--- thay đổi văn bản đối tượng
   if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
     {
      Print(__FUNCTION__,
            ": không thể thay đổi văn bản! Mã lỗi = ",GetLastError());
      return(false);
     }
//--- thực thi thành công
   return(true);
  }
//+------------------------------------------------------------------+
//| Di chuyển đối tượng Sự kiện                                      |
//+------------------------------------------------------------------+
bool EventMove(const long   chart_ID=0,   // ID biểu đồ
               const string name="Event", // Tên sự kiện
               datetime     time=0)       // Thời gian
  {
//--- nếu thời gian không được thiết lập, di chuyển sự kiện đến thanh cuối cùng
   if(!time)
      time=TimeCurrent();
//--- đặt lại giá trị lỗi
   ResetLastError();
//--- di chuyển đối tượng
   if(!ObjectMove(chart_ID,name,0,time,0))
     {
      Print(__FUNCTION__,
            ": không thể di chuyển đối tượng \"Event\"! Mã lỗi = ",GetLastError());
      return(false);
     }
//--- thực thi thành công
   return(true);
  }
//+------------------------------------------------------------------+
//| Xóa đối tượng Sự kiện                                            |
//+------------------------------------------------------------------+
bool EventDelete(const long   chart_ID=0,   // ID biểu đồ
                 const string name="Event") // Tên sự kiện
  {
//--- đặt lại giá trị lỗi
   ResetLastError();
//--- xóa đối tượng
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": không thể xóa đối tượng \"Event\"! Mã lỗi = ",GetLastError());
      return(false);
     }
//--- thực thi thành công
   return(true);
  }
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- kiểm tra tính chính xác của các tham số đầu vào
   if(InpDate<0 || InpDate>100)
     {
      Print("Lỗi! Giá trị tham số đầu vào không chính xác!");
      return;
     }
//--- số thanh hiển thị trong cửa sổ biểu đồ
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- mảng để lưu trữ các giá trị ngày sẽ được sử dụng
//--- để thiết lập và thay đổi tọa độ điểm neo của đối tượng Sự kiện
   datetime date[];
//--- cấp phát bộ nhớ
   ArrayResize(date,bars);
//--- điền mảng ngày
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
      return;
     }
//--- xác định các điểm để tạo đối tượng
   int d=InpDate*(bars-1)/100;
//--- tạo đối tượng Sự kiện
   if(!EventCreate(0,InpName,0,InpText,date[d],InpColor,InpWidth,
      InpBack,InpSelection,InpHidden,InpZOrder))
     {
      return;
     }
//--- vẽ lại biểu đồ và đợi 1 giây
   ChartRedraw();
   Sleep(1000);
//--- bây giờ, di chuyển đối tượng
//--- bộ đếm vòng lặp
   int h_steps=bars/2;
//--- di chuyển đối tượng
   for(int i=0;i<h_steps;i++)
     {
      //--- sử dụng giá trị tiếp theo
      if(d<bars-1)
         d+=1;
      //--- di chuyển điểm
      if(!EventMove(0,InpName,date[d]))
         return;
      //--- kiểm tra nếu hoạt động của script bị tắt buộc
      if(IsStopped())
         return;
      //--- vẽ lại biểu đồ
      ChartRedraw();
      // 0.05 giây trì hoãn
      Sleep(50);
     }
//--- 1 giây trì hoãn
   Sleep(1000);
//--- xóa kênh khỏi biểu đồ
   EventDelete(0,InpName);
   ChartRedraw();
//--- 1 giây trì hoãn
   Sleep(1000);
//---
  }