OBJ_ELLIOTWAVE5
Sóng động lực Elliott.
Ghi chú
Đối với Elliott Motive Wave, có thể bật/tắt chế độ kết nối các điểm bằng đường thẳng (thuộc tính OBJPROP_DRAWLINES), cũng như thiết lập cấp độ định vị sóng (từ danh sách ENUM_ELLIOT_WAVE_DEGREE).
Ví dụ
Script sau tạo và di chuyển sóng động lực Elliott trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script vẽ \"Elliott Motive Wave\"."
#property description "Tọa độ điểm neo được thiết lập theo phần trăm kích thước của"
#property description "cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string `InpName`="ElliotWave5"; // Tên đối tượng
input int `InpDate1`=10; // Ngày của điểm thứ 1, %
input int `InpPrice1`=90; // Giá của điểm thứ 1, %
input int `InpDate2`=20; // Ngày của điểm thứ 2, %
input int `InpPrice2`=40; // Giá của điểm thứ 2, %
input int `InpDate3`=30; // Ngày của điểm thứ 3, %
input int `InpPrice3`=60; // Giá của điểm thứ 3, %
input int `InpDate4`=40; // Ngày của điểm thứ 4, %
input int `InpPrice4`=10; // Giá của điểm thứ 4, %
input int `InpDate5`=60; // Ngày của điểm thứ 5, %
input int `InpPrice5`=40; // Giá của điểm thứ 5, %
input ENUM_ELLIOT_WAVE_DEGREE `InpDegree`=ELLIOTT_MINOR; // Cấp độ
input bool `InpDrawLines`=true; // Hiển thị các đường
input color `InpColor`=clrRed; // Màu của các đường
input ENUM_LINE_STYLE `InpStyle`=STYLE_DASH; // Kiểu của các đường
input int `InpWidth`=2; // Độ dày của các đường
input bool `InpBack`=false; // Đối tượng nền
input bool `InpSelection`=true; // Làm nổi bật để di chuyển
input bool `InpHidden`=true; // Ẩn trong danh sách đối tượng
input long `InpZOrder`=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo "Elliott Motive Wave" bởi các tọa độ đã cho |
//+------------------------------------------------------------------+
bool ElliotWave5Create(const long chart_ID=0, // ID biểu đồ
const string name="ElliotWave5", // Tên sóng
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time1=0, // Thời gian điểm thứ nhất
double price1=0, // Giá điểm thứ nhất
datetime time2=0, // Thời gian điểm thứ hai
double price2=0, // Giá điểm thứ hai
datetime time3=0, // Thời gian điểm thứ ba
double price3=0, // Giá điểm thứ ba
datetime time4=0, // Thời gian điểm thứ tư
double price4=0, // Giá điểm thứ tư
datetime time5=0, // Thời gian điểm thứ năm
double price5=0, // Giá điểm thứ năm
const ENUM_ELLIOT_WAVE_DEGREE degree=ELLIOTT_MINUETTE, // Cấp độ
const bool draw_lines=true, // Hiển thị các đường
const color clr=clrRed, // Màu đối tượng
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu của các đường
const int width=1, // Độ dày của các đường
const bool back=false, // Ở nền
const bool selection=true, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeElliotWave5EmptyPoints(time1,price1,time2,price2,time3,price3,time4,price4,time5,price5);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- Tạo "Elliott Motive Wave" bởi các tọa độ đã cho
if(!ObjectCreate(chart_ID,name,OBJ_ELLIOTWAVE5,sub_window,time1,price1,time2,price2,time3,
price3,time4,price4,time5,price5))
{
Print(__FUNCTION__,
": không thể tạo \"Elliott Motive Wave\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập cấp độ (kích thước sóng)
ObjectSetInteger(chart_ID,name,OBJPROP_DEGREE,degree);
//--- bật (true) hoặc tắt (false) chế độ hiển thị các đường
ObjectSetInteger(chart_ID,name,OBJPROP_DRAWLINES,draw_lines);
//--- thiết lập màu của đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập độ dày của các đường
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ làm nổi bật kênh để di chuyển
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được làm nổi bật và di chuyển theo mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép làm nổi bật và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho việc nhận sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo của Sóng động lực Elliott |
//+------------------------------------------------------------------+
bool ElliotWave5PointChange(const long chart_ID=0, // ID biểu đồ
const string name="ElliotWave5", // Tên đối tượng
const int point_index=0, // Chỉ số điểm neo
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa Sóng động lực Elliott |
//+------------------------------------------------------------------+
bool ElliotWave5Delete(const long chart_ID=0, // ID biểu đồ
const string name="ElliotWave5") // Tên đối tượng
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa đối tượng
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa \"Elliott Motive Wave\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị của các điểm neo của Sóng động lực Elliott và |
//| thiết lập giá trị mặc định cho các điểm trống |
//+------------------------------------------------------------------+
void ChangeElliotWave5EmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3,
datetime &time4,double &price4,
datetime &time5,double &price5)
{
//--- mảng để nhận thời gian mở của 10 thanh cuối cùng
datetime temp[];
ArrayResize(temp,10);
//--- nhận dữ liệu
CopyTime(Symbol(),Period(),TimeCurrent(),10,temp);
//--- nhận giá trị của một điểm trên biểu đồ hiện tại
double point=SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- nếu thời gian của điểm thứ nhất không được thiết lập, nó sẽ cách thanh cuối 9 thanh
if(!time1)
time1=temp[0];
//--- nếu giá của điểm thứ nhất không được thiết lập, nó sẽ có giá trị Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- nếu thời gian của điểm thứ hai không được thiết lập, nó sẽ cách thanh cuối 7 thanh
if(!time2)
time2=temp[2];
//--- nếu giá của điểm thứ hai không được thiết lập, di chuyển nó thấp hơn điểm thứ nhất 300 điểm
if(!price2)
price2=price1-300*point;
//--- nếu thời gian của điểm thứ ba không được thiết lập, nó sẽ cách thanh cuối 5 thanh
if(!time3)
time3=temp[4];
//--- nếu giá của điểm thứ ba không được thiết lập, di chuyển nó thấp hơn điểm thứ nhất 250 điểm
if(!price3)
price3=price1-250*point;
//--- nếu thời gian của điểm thứ tư không được thiết lập, nó sẽ cách thanh cuối 3 thanh
if(!time4)
time4=temp[6];
//--- nếu giá của điểm thứ tư không được thiết lập, di chuyển nó thấp hơn điểm thứ nhất 550 điểm
if(!price4)
price4=price1-550*point;
//--- nếu thời gian của điểm thứ năm không được thiết lập, nó sẽ nằm trên thanh cuối
if(!time5)
time5=temp[9];
//--- nếu giá của điểm thứ năm không được thiết lập, di chuyển nó thấp hơn điểm thứ nhất 450 điểm
if(!price5)
price5=price1-450*point;
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(`InpDate1`<0 || `InpDate1`>100 || `InpPrice1`<0 || `InpPrice1`>100 ||
`InpDate2`<0 || `InpDate2`>100 || `InpPrice2`<0 || `InpPrice2`>100 ||
`InpDate3`<0 || `InpDate3`>100 || `InpPrice3`<0 || `InpPrice3`>100 ||
`InpDate4`<0 || `InpDate4`>100 || `InpPrice4`<0 || `InpPrice4`>100 ||
`InpDate5`<0 || `InpDate5`>100 || `InpPrice5`<0 || `InpPrice5`>100)
{
Print("Lỗi! Giá trị không chính xác của các tham số đầu vào!");
return;
}
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để thiết lập và thay đổi tọa độ điểm neo của đối tượng
datetime date[];
double price[];
//--- phân bổ bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ Sóng động lực Elliott
int d1=`InpDate1`*(bars-1)/100;
int d2=`InpDate2`*(bars-1)/100;
int d3=`InpDate3`*(bars-1)/100;
int d4=`InpDate4`*(bars-1)/100;
int d5=`InpDate5`*(bars-1)/100;
int p1=`InpPrice1`*(accuracy-1)/100;
int p2=`InpPrice2`*(accuracy-1)/100;
int p3=`InpPrice3`*(accuracy-1)/100;
int p4=`InpPrice4`*(accuracy-1)/100;
int p5=`InpPrice5`*(accuracy-1)/100;
//--- Tạo Sóng động lực Elliott
if(!ElliotWave5Create(0,`InpName`,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
date[d4],price[p4],date[d5],price[p5],`InpDegree`,`InpDrawLines`,`InpColor`,`InpStyle`,`InpWidth`,
`InpBack`,`InpSelection`,`InpHidden`,`InpZOrder`))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển các điểm neo
//--- bộ đếm vòng lặp
int v_steps=accuracy/5;
//--- di chuyển điểm neo thứ năm
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p5<accuracy-1)
p5+=1;
//--- di chuyển điểm
if(!ElliotWave5PointChange(0,`InpName`,4,date[d5],price[p5]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
v_steps=accuracy/5;
//--- di chuyển điểm neo thứ hai và thứ ba
for(int i=0;i<v_steps;i++)
{
//--- sử dụng các giá trị tiếp theo
if(p2<accuracy-1)
p2+=1;
if(p3>1)
p3-=1;
//--- dịch chuyển các điểm
if(!ElliotWave5PointChange(0,`InpName`,1,date[d2],price[p2]))
return;
if(!ElliotWave5PointChange(0,`InpName`,2,date[d3],price[p3]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- bộ đếm vòng lặp
v_steps=accuracy*4/5;
//--- di chuyển điểm neo thứ nhất và thứ tư
for(int i=0;i<v_steps;i++)
{
//--- sử dụng các giá trị tiếp theo
if(p1>1)
p1-=1;
if(p4<accuracy-1)
p4+=1;
//--- dịch chuyển các điểm
if(!ElliotWave5PointChange(0,`InpName`,0,date[d1],price[p1]))
return;
if(!ElliotWave5PointChange(0,`InpName`,3,date[d4],price[p4]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa đối tượng khỏi biểu đồ
ElliotWave5Delete(0,`InpName`);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}