OBJ_BITMAP_LABEL
Đối tượng Nhãn Bitmap.
Ghi chú
Vị trí điểm neo so với nhãn có thể được chọn từ danh sách liệt kê ENUM_ANCHOR_POINT. Tọa độ điểm neo được thiết lập bằng pixel.
Bạn cũng có thể chọn góc neo của bitmap từ danh sách liệt kê ENUM_BASE_CORNER.
Đối với nhãn bitmap, bạn có thể chọn phạm vi hiển thị của một hình ảnh.
Ví dụ
Script sau tạo ra một số bitmap trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên trạng trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo đối tượng \"Nhãn Bitmap\"."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="BmpLabel"; // Tên nhãn
input string InpFileOn="\\Images\\dollar.bmp"; // Tên tệp cho chế độ Bật
input string InpFileOff="\\Images\\euro.bmp"; // Tên tệp cho chế độ Tắt
input bool InpState=false; // Nhãn được nhấn/thả
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // Góc biểu đồ để neo
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_CENTER; // Loại điểm neo
input color InpColor=clrRed; // Màu viền khi được làm nổi bật
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // Kiểu đường viền khi được làm nổi bật
input int InpPointWidth=1; // Kích thước điểm để di chuyển
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo đối tượng Nhãn Bitmap |
//+------------------------------------------------------------------+
bool BitmapLabelCreate(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel", // Tên nhãn
const int sub_window=0, // Chỉ số cửa sổ phụ
const int x=0, // Tọa độ X
const int y=0, // Tọa độ Y
const string file_on="", // Hình ảnh ở chế độ Bật
const string file_off="", // Hình ảnh ở chế độ Tắt
const int width=0, // Tọa độ X phạm vi hiển thị
const int height=0, // Tọa độ Y phạm vi hiển thị
const int x_offset=10, // Dịch chuyển phạm vi hiển thị theo trục X
const int y_offset=10, // Dịch chuyển phạm vi hiển thị theo trục Y
const bool state=false, // Nhấn/thả
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // Góc biểu đồ để neo
const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // Loại điểm neo
const color clr=clrRed, // Màu viền khi được làm nổi bật
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường khi được làm nổi bật
const int point_width=1, // Kích thước điểm di chuyển
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo nhãn bitmap
if(!ObjectCreate(chart_ID,name,OBJ_BITMAP_LABEL,sub_window,0,0))
{
Print(__FUNCTION__,
": không thể tạo đối tượng \"Nhãn Bitmap\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập hình ảnh cho chế độ Bật và Tắt
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,0,file_on))
{
Print(__FUNCTION__,
": không thể tải hình ảnh cho chế độ Bật! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,1,file_off))
{
Print(__FUNCTION__,
": không thể tải hình ảnh cho chế độ Tắt! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập tọa độ nhãn
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- thiết lập phạm vi hiển thị cho hình ảnh; nếu giá trị chiều rộng hoặc chiều cao
//--- vượt quá chiều rộng và chiều cao (tương ứng) của hình ảnh nguồn,
//--- nó sẽ không được vẽ; ngược lại,
//--- chỉ phần tương ứng với các giá trị này được vẽ
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- thiết lập phần của hình ảnh sẽ được hiển thị trong phạm vi hiển thị
//--- phần mặc định là vùng trên cùng bên trái của hình ảnh; các giá trị cho phép
//--- thực hiện dịch chuyển từ vùng này để hiển thị phần khác của hình ảnh
ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset);
ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset);
//--- xác định trạng thái của nhãn (nhấn hoặc thả)
ObjectSetInteger(chart_ID,name,OBJPROP_STATE,state);
//--- thiết lập góc của biểu đồ, mà tọa độ điểm được xác định tương đối với nó
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- thiết lập loại điểm neo
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- thiết lập màu viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập kích thước điểm neo để di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thiết lập hình ảnh mới cho đối tượng Nhãn Bitmap |
//+------------------------------------------------------------------+
bool BitmapLabelSetImage(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel", // Tên nhãn
const int on_off=0, // Bộ điều chỉnh (Bật hoặc Tắt)
const string file="") // Đường dẫn đến tệp
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thiết lập đường dẫn đến tệp hình ảnh
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,on_off,file))
{
Print(__FUNCTION__,
": không thể tải hình ảnh! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển đối tượng Nhãn Bitmap |
//+------------------------------------------------------------------+
bool BitmapLabelMove(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel", // Tên nhãn
const int x=0, // Tọa độ X
const int y=0) // Tọa độ Y
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ X của đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": không thể di chuyển tọa độ Y của đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi kích thước phạm vi hiển thị (đối tượng) |
//+------------------------------------------------------------------+
bool BitmapLabelChangeSize(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel", // Tên nhãn
const int width=0, // Chiều rộng nhãn
const int height=0) // Chiều cao nhãn
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi kích thước đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": không thể thay đổi chiều rộng đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": không thể thay đổi chiều cao đối tượng! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+--------------------------------------------------------------------+
//| Thay đổi tọa độ góc trên bên trái của phạm vi hiển thị |
//+--------------------------------------------------------------------+
bool BitmapLabelMoveVisibleArea(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel", // Tên nhãn
const int x_offset=0, // Tọa độ X của phạm vi hiển thị
const int y_offset=0) // Tọa độ Y của phạm vi hiển thị
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi tọa độ phạm vi hiển thị của đối tượng
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset))
{
Print(__FUNCTION__,
": không thể thay đổi tọa độ X của phạm vi hiển thị! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset))
{
Print(__FUNCTION__,
": không thể thay đổi tọa độ Y của phạm vi hiển thị! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa đối tượng "Nhãn Bitmap" |
//+------------------------------------------------------------------+
bool BitmapLabelDelete(const long chart_ID=0, // ID biểu đồ
const string name="BmpLabel") // Tên nhãn
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nhãn
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa đối tượng \"Nhãn Bitmap\"! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kích thước cửa sổ biểu đồ
long x_distance;
long y_distance;
//--- thiết lập kích thước cửa sổ
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Không thể lấy chiều rộng biểu đồ! Mã lỗi = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Không thể lấy chiều cao biểu đồ! Mã lỗi = ",GetLastError());
return;
}
//--- xác định tọa độ nhãn bitmap
int x=(int)x_distance/2;
int y=(int)y_distance/2;
//--- thiết lập kích thước nhãn và tọa độ phạm vi hiển thị
int width=32;
int height=32;
int x_offset=0;
int y_offset=0;
//--- đặt nhãn bitmap vào giữa cửa sổ
if(!BitmapLabelCreate(0,InpName,0,x,y,InpFileOn,InpFileOff,width,height,x_offset,y_offset,InpState,
InpCorner,InpAnchor,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi một giây
ChartRedraw();
Sleep(1000);
//--- thay đổi kích thước phạm vi hiển thị của nhãn trong vòng lặp
for(int i=0;i<6;i++)
{
//--- thay đổi kích thước phạm vi hiển thị
width--;
height--;
if(!BitmapLabelChangeSize(0,InpName,width,height))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.3 giây trì hoãn
Sleep(300);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- thay đổi tọa độ phạm vi hiển thị của nhãn trong vòng lặp
for(int i=0;i<2;i++)
{
//--- thay đổi tọa độ phạm vi hiển thị
x_offset++;
y_offset++;
if(!BitmapLabelMoveVisibleArea(0,InpName,x_offset,y_offset))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.3 giây trì hoãn
Sleep(300);
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa nhãn
BitmapLabelDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}