OBJ_BITMAP
Đối tượng Bitmap.
Ghi chú
Đối với đối tượng Bitmap, bạn có thể chọn phạm vi hiển thị của một hình ảnh qua ENUM_OBJECT_PROPERTY.
Ví dụ
Script sau tạo ra một số bitmap trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này nguyên trạng trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo bitmap trong cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpFile="\\Images\\dollar.bmp"; // Tên tệp bitmap
input int InpWidth=24; // Tọa độ X của phạm vi hiển thị
input int InpHeight=24; // Tọa độ Y của phạm vi hiển thị
input int InpXOffset=4; // Dịch chuyển phạm vi hiển thị theo trục X
input int InpYOffset=4; // Dịch chuyển phạm vi hiển thị theo trục Y
input color InpColor=clrRed; // Màu viền khi được làm nổi bật
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // Kiểu đường viền khi được làm nổi bật
input int InpPointWidth=1; // Kích thước điểm để di chuyển
input bool InpBack=false; // Đối tượng nền
input bool InpSelection=false; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo bitmap trong cửa sổ biểu đồ |
//+------------------------------------------------------------------+
bool BitmapCreate(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap", // Tên bitmap
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian điểm neo
double price=0, // Giá điểm neo
const string file="", // Tên tệp bitmap
const int width=10, // Tọa độ X của phạm vi hiển thị
const int height=10, // Tọa độ Y của phạm vi hiển thị
const int x_offset=0, // Dịch chuyển phạm vi hiển thị theo trục X
const int y_offset=0, // Dịch chuyển phạm vi hiển thị theo trục Y
const color clr=clrRed, // Màu viền khi được làm nổi bật
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường khi được làm nổi bật
const int point_width=1, // Kích thước điểm di chuyển
const bool back=false, // Ở nền
const bool selection=false, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeBitmapEmptyPoint(time,price);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo bitmap
if(!ObjectCreate(chart_ID,name,OBJ_BITMAP,sub_window,time,price))
{
Print(__FUNCTION__,
": không thể tạo bitmap trong cửa sổ biểu đồ! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập đường dẫn đến tệp hình ảnh
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": không thể tải hình ảnh! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập phạm vi hiển thị cho hình ảnh; nếu giá trị chiều rộng hoặc chiều cao
//--- vượt quá chiều rộng và chiều cao (tương ứng) của hình ảnh nguồn,
//--- nó sẽ không được vẽ; ngược lại,
//--- chỉ phần tương ứng với các giá trị này được vẽ
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- thiết lập phần của hình ảnh sẽ được hiển thị trong phạm vi hiển thị
//--- phần mặc định là vùng trên cùng bên trái của hình ảnh; các giá trị cho phép
//--- thực hiện dịch chuyển từ vùng này để hiển thị phần khác của hình ảnh
ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset);
ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset);
//--- thiết lập màu viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền khi chế độ làm nổi bật được bật
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập kích thước điểm neo để di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thiết lập hình ảnh mới cho bitmap |
//+------------------------------------------------------------------+
bool BitmapSetImage(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap", // Tên bitmap
const string file="") // Đường dẫn đến tệp
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thiết lập đường dẫn đến tệp hình ảnh
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": không thể tải hình ảnh! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển bitmap trong cửa sổ biểu đồ |
//+------------------------------------------------------------------+
bool BitmapMove(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap", // Tên bitmap
datetime time=0, // Thời gian điểm neo
double price=0) // Giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Thay đổi kích thước phạm vi hiển thị (bitmap) |
//+------------------------------------------------------------------+
bool BitmapChangeSize(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap", // Tên bitmap
const int width=0, // Chiều rộng bitmap
const int height=0) // Chiều cao bitmap
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi kích thước bitmap
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": không thể thay đổi chiều rộng bitmap! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": không thể thay đổi chiều cao bitmap! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+--------------------------------------------------------------------+
//| Thay đổi tọa độ góc trên bên trái của phạm vi hiển thị |
//+--------------------------------------------------------------------+
bool BitmapMoveVisibleArea(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap", // Tên bitmap
const int x_offset=0, // Tọa độ X của phạm vi hiển thị
const int y_offset=0) // Tọa độ Y của phạm vi hiển thị
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- thay đổi tọa độ phạm vi hiển thị của bitmap
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset))
{
Print(__FUNCTION__,
": không thể thay đổi tọa độ X của phạm vi hiển thị! Mã lỗi = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset))
{
Print(__FUNCTION__,
": không thể thay đổi tọa độ Y của phạm vi hiển thị! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa bitmap |
//+------------------------------------------------------------------+
bool BitmapDelete(const long chart_ID=0, // ID biểu đồ
const string name="Bitmap") // Tên bitmap
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nhãn
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa bitmap! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị điểm neo và thiết lập giá trị mặc định |
//| cho những điểm trống |
//+------------------------------------------------------------------+
void ChangeBitmapEmptyPoint(datetime &time,double &price)
{
//--- nếu thời gian của điểm không được thiết lập, nó sẽ nằm trên thanh hiện tại
if(!time)
time=TimeCurrent();
//--- nếu giá của điểm không được thiết lập, nó sẽ có giá trị Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // mảng lưu trữ ngày của các thanh hiển thị
double close[]; // mảng lưu trữ giá đóng cửa
//--- tên tệp bitmap
string file="\\Images\\dollar.bmp";
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- cấp phát bộ nhớ
ArrayResize(date,bars);
ArrayResize(close,bars);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá đóng cửa
if(CopyClose(Symbol(),Period(),0,bars,close)==-1)
{
Print("Không thể sao chép giá trị giá đóng cửa! Mã lỗi = ",GetLastError());
return;
}
//--- xác định tần suất hiển thị hình ảnh
int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- xác định bước
int step=1;
switch(scale)
{
case 0:
step=27;
break;
case 1:
step=14;
break;
case 2:
step=7;
break;
case 3:
step=4;
break;
case 4:
step=2;
break;
}
//--- tạo bitmap cho giá trị thanh Cao và Thấp (có khoảng cách)
for(int i=0;i<bars;i+=step)
{
//--- tạo các bitmap
if(!BitmapCreate(0,"Bitmap_"+(string)i,0,date[i],close[i],InpFile,InpWidth,InpHeight,InpXOffset,
InpYOffset,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//--- nửa giây trì hoãn
Sleep(500);
//--- xóa các ký hiệu Bán
for(int i=0;i<bars;i+=step)
{
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
//--- vẽ lại biểu đồ
ChartRedraw();
// 0.05 giây trì hoãn
Sleep(50);
}
//---
}