OBJ_ARROW_RIGHT_PRICE
Nhãn Giá Bên Phải
Ví dụ
Script sau tạo và di chuyển nhãn giá bên phải trên biểu đồ. Các hàm đặc biệt đã được phát triển để tạo và thay đổi thuộc tính của đối tượng đồ họa. Bạn có thể sử dụng các hàm này "nguyên trạng" trong các ứng dụng của riêng bạn.
cpp
//--- mô tả
#property description "Script tạo nhãn giá bên phải trên biểu đồ."
#property description "Tọa độ điểm neo được thiết lập theo"
#property description "phần trăm của kích thước cửa sổ biểu đồ."
//--- hiển thị cửa sổ tham số đầu vào khi khởi chạy script
#property script_show_inputs
//--- tham số đầu vào của script
input string InpName="RightPrice"; // Tên nhãn giá
input int InpDate=0; // Ngày điểm neo tính bằng %
input int InpPrice=90; // Giá điểm neo tính bằng %
input color InpColor=clrRed; // Màu nhãn giá
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID;// Kiểu đường viền
input int InpWidth=2; // Kích thước nhãn giá
input bool InpBack=false; // Nhãn ở nền
input bool InpSelection=true; // Làm nổi bật để di chuyển
input bool InpHidden=true; // Ẩn trong danh sách đối tượng
input long InpZOrder=0; // Độ ưu tiên cho cú nhấp chuột
//+------------------------------------------------------------------+
//| Tạo nhãn giá bên phải |
//+------------------------------------------------------------------+
bool ArrowRightPriceCreate(const long chart_ID=0, // ID biểu đồ
const string name="RightPrice", // Tên nhãn giá
const int sub_window=0, // Chỉ số cửa sổ phụ
datetime time=0, // Thời gian điểm neo
double price=0, // Giá điểm neo
const color clr=clrRed, // Màu nhãn giá
const ENUM_LINE_STYLE style=STYLE_SOLID, // Kiểu đường viền
const int width=1, // Kích thước nhãn giá
const bool back=false, // Ở nền
const bool selection=true, // Làm nổi bật để di chuyển
const bool hidden=true, // Ẩn trong danh sách đối tượng
const long z_order=0) // Độ ưu tiên cho cú nhấp chuột
{
//--- thiết lập tọa độ điểm neo nếu chúng chưa được thiết lập
ChangeArrowEmptyPoint(time,price);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- tạo nhãn giá
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_RIGHT_PRICE,sub_window,time,price))
{
Print(__FUNCTION__,
": không thể tạo nhãn giá bên phải! Mã lỗi = ",GetLastError());
return(false);
}
//--- thiết lập màu nhãn
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- thiết lập kiểu đường viền
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- thiết lập kích thước nhãn
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- hiển thị ở tiền cảnh (false) hoặc nền (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- bật (true) hoặc tắt (false) chế độ di chuyển nhãn bằng chuột
//--- khi tạo một đối tượng đồ họa bằng hàm ObjectCreate, đối tượng không thể
//--- được làm nổi bật và di chuyển theo mặc định. Trong phương thức này, tham số selection
//--- mặc định là true, cho phép làm nổi bật và di chuyển đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ẩn (true) hoặc hiển thị (false) tên đối tượng đồ họa trong danh sách đối tượng
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- thiết lập độ ưu tiên cho sự kiện nhấp chuột trên biểu đồ
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Di chuyển điểm neo |
//+------------------------------------------------------------------+
bool ArrowRightPriceMove(const long chart_ID=0, // ID biểu đồ
const string name="RightPrice", // Tên nhãn
datetime time=0, // Tọa độ thời gian điểm neo
double price=0) // Tọa độ giá điểm neo
{
//--- nếu vị trí điểm không được thiết lập, di chuyển nó đến thanh hiện tại với giá Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- đặt lại giá trị lỗi
ResetLastError();
//--- di chuyển điểm neo
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": không thể di chuyển điểm neo! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Xóa nhãn giá bên phải khỏi biểu đồ |
//+------------------------------------------------------------------+
bool ArrowRightPriceDelete(const long chart_ID=0, // ID biểu đồ
const string name="RightPrice") // Tên nhãn
{
//--- đặt lại giá trị lỗi
ResetLastError();
//--- xóa nhãn
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": không thể xóa nhãn giá bên phải! Mã lỗi = ",GetLastError());
return(false);
}
//--- thực thi thành công
return(true);
}
//+------------------------------------------------------------------+
//| Kiểm tra giá trị điểm neo và thiết lập giá trị mặc định |
//| cho các điểm trống |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- nếu thời gian của điểm không được thiết lập, nó sẽ ở trên thanh hiện tại
if(!time)
time=TimeCurrent();
//--- nếu giá của điểm không được thiết lập, nó sẽ có giá trị Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Hàm bắt đầu chương trình Script |
//+------------------------------------------------------------------+
void OnStart()
{
//--- kiểm tra tính đúng đắn của các tham số đầu vào
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Lỗi! Giá trị không chính xác của các tham số đầu vào!");
return;
}
//--- số lượng thanh hiển thị trong cửa sổ biểu đồ
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- kích thước mảng giá
int accuracy=1000;
//--- mảng để lưu trữ giá trị ngày và giá sẽ được sử dụng
//--- để thiết lập và thay đổi tọa độ điểm neo của nhãn
datetime date[];
double price[];
//--- phân bổ bộ nhớ
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- điền mảng ngày
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Không thể sao chép giá trị thời gian! Mã lỗi = ",GetLastError());
return;
}
//--- điền mảng giá
//--- tìm giá trị cao nhất và thấp nhất của biểu đồ
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- xác định bước thay đổi của giá và điền mảng
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- xác định các điểm để vẽ nhãn
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- tạo nhãn giá bên phải trên biểu đồ
if(!ArrowRightPriceCreate(0,InpName,0,date[d],price[p],InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- vẽ lại biểu đồ và đợi 1 giây
ChartRedraw();
Sleep(1000);
//--- bây giờ, di chuyển điểm neo
//--- bộ đếm vòng lặp
int v_steps=accuracy*4/5;
//--- di chuyển điểm neo
for(int i=0;i<v_steps;i++)
{
//--- sử dụng giá trị tiếp theo
if(p>1)
p-=1;
//--- di chuyển điểm
if(!ArrowRightPriceMove(0,InpName,date[d],price[p]))
return;
//--- kiểm tra nếu hoạt động của script bị tắt buộc
if(IsStopped())
return;
//--- vẽ lại biểu đồ
ChartRedraw();
}
//--- 1 giây trì hoãn
Sleep(1000);
//--- xóa nhãn khỏi biểu đồ
ArrowRightPriceDelete(0,InpName);
ChartRedraw();
//--- 1 giây trì hoãn
Sleep(1000);
//---
}