PeriodSeconds

Hàm này trả về số giây trong một khoảng thời gian.

int  PeriodSeconds(
   ENUM_TIMEFRAMES  period=PERIOD_CURRENT      // khoảng thời gian biểu đồ
   );

Tham số

period=PERIOD_CURRENT

[truyền vào] Giá trị của khoảng thời gian biểu đồ từ bảng liệt kê ENUM_TIMEFRAMES. Nếu tham số không được chỉ định, hàm trả về số giây của khoảng thời gian biểu đồ hiện tại mà chương trình đang chạy.

Giá trị trả về

Số giây trong khoảng thời gian đã chọn.

Ví dụ:

//--- tham số đầu vào
input ENUM_TIMEFRAMES InpPeriod1 = PERIOD_CURRENT;   // Khoảng thời gian đầu tiên
input ENUM_TIMEFRAMES InpPeriod2 = PERIOD_M1;        // Khoảng thời gian thứ hai

//+------------------------------------------------------------------+
//| Hàm khởi động chương trình script                                |
//+------------------------------------------------------------------+
void OnStart()
  {
   //--- lấy số giây trong các khoảng thời gian biểu đồ InpPeriod1 và InpPeriod2
   int sec1=PeriodSeconds(InpPeriod1);
   int sec2=PeriodSeconds(InpPeriod2);
   //--- hiển thị các giá trị nhận được trong nhật ký
   PrintFormat("Số giây trong khoảng thời gian %s: %lu, trong khoảng thời gian %s: %lu",TimeframeDescription(InpPeriod1),sec1,TimeframeDescription(InpPeriod2),sec2);
   //--- tính toán有多少thanh giá của khoảng thời gian biểu đồ InpPeriod2 chứa trong một thanh giá với khoảng thời gian biểu đồ InpPeriod1
   int res=sec1/sec2;
   if(res==0)
      res=1;
   //--- hiển thị giá trị thu được trong nhật ký
   PrintFormat("Một thanh giá %s chứa %d thanh giá %s",TimeframeDescription(InpPeriod1),res,TimeframeDescription(InpPeriod2));
   /*
   Kết quả:
   Số giây trong khoảng thời gian M5: 300, trong khoảng thời gian M1: 60
   Một thanh giá M5 chứa 5 thanh giá M1
   */
  }
//+------------------------------------------------------------------+
//| Trả về tên khoảng thời gian                                      |
//+------------------------------------------------------------------+
string TimeframeDescription(const ENUM_TIMEFRAMES period)
  {
   return(StringSubstr(EnumToString(period==PERIOD_CURRENT ? Period() : period), 7));
  }

Xem thêm

_Period, Chart timeframes, Date and Time, Visibility of objects