CryptEncode

Chuyển đổi dữ liệu từ mảng bằng phương pháp được chỉ định.

int  CryptEncode(
   ENUM_CRYPT_METHOD   method,        // phương pháp
   const uchar&        data[],        // mảng nguồn
   const uchar&        key[],         // khóa
   uchar&              result[]       // mảng đích
   );

Tham số

method

[truyền vào] Phương pháp chuyển đổi dữ liệu. Có thể là một trong những giá trị của bảng liệt kê ENUM_CRYPT_METHOD.

data[]

[truyền vào] Mảng nguồn.

key[]

[truyền vào] Mảng khóa.

result[]

[truyền ra] Mảng đích.

Giá trị trả về

Số byte trong mảng đích hoặc 0 trong trường hợp lỗi. Để lấy thông tin về lỗi, hãy gọi hàm GetLastError().

Ví dụ:

//+------------------------------------------------------------------+
//| ArrayToHex                                                       |
//+------------------------------------------------------------------+
string ArrayToHex(uchar &arr[],int count=-1)
  {
   string res="";
   //--- kiểm tra
   if(count<0 || count>ArraySize(arr))
      count=ArraySize(arr);
   //--- chuyển đổi sang chuỗi HEX
   for(int i=0; i<count; i++)
      res+=StringFormat("%.2X",arr[i]);
   //---
   return(res);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string text="The quick brown fox jumps over the lazy dog";
   string keystr="ABCDEFG";
   uchar src[],dst[],key[];
   //--- chuẩn bị khóa
   StringToCharArray(keystr,key);
   //--- sao chép văn bản vào mảng nguồn src[]
   StringToCharArray(text,src);
   //--- in dữ liệu ban đầu
   PrintFormat("Dữ liệu ban đầu: kích thước=%d, chuỗi='%s'",ArraySize(src),CharArrayToString(src));
   //--- mã hóa src[] bằng khóa DES 56-bit trong key[]
   int res=CryptEncode(CRYPT_DES,src,key,dst);
   //--- kiểm tra lỗi
   if(res>0)
     {
      //--- in dữ liệu đã mã hóa
      PrintFormat("Dữ liệu đã mã hóa: kích thước=%d %s",res,ArrayToHex(dst));
      //--- giải mã dst[] về src[]
      res=CryptDecode(CRYPT_DES,dst,key,src);
      //--- kiểm tra lỗi
      if(res>0)
        {
         //--- in dữ liệu đã giải mã
         PrintFormat("Dữ liệu đã giải mã: kích thước=%d, chuỗi='%s'",ArraySize(src),CharArrayToString(src));
        }
      else
         Print("Lỗi trong CryptDecode. Mã lỗi=",GetLastError());
     }
   else
      Print("Lỗi trong CryptEncode. Mã lỗi=",GetLastError());
  }

Xem thêm

Array Functions, CryptDecode()